#!/usr/bin/perl -w
    use Tk;
    use strict;

    # Create B<MainWindow> and canvas
    my $mw = MainWindow->new;
    my $canvas = $mw->Canvas;
    $canvas->pack(-expand => 1, -fill => 'both');

    # Create various items
    create_item($canvas, 1, 1, 'circle', 'blue', 'Jane');
    create_item($canvas, 4, 4, 'circle', 'red', 'Peter');
    create_item($canvas, 4, 1, 'square', 'blue', 'James');
    create_item($canvas, 1, 4, 'square', 'red', 'Patricia');

    # Single-clicking with left on a 'circle' item invokes a procedure
    $canvas->bind('circle', '<1>' => sub {handle_circle($canvas)});
    # Double-clicking with left on a 'blue' item invokes a procedure
    $canvas->bind('blue', '<Double-1>' => sub {handle_blue($canvas)});
    MainLoop;

    # Create an item; use parameters as tags (this is not a default!)
    sub create_item {
        my ($can, $x, $y, $form, $color, $name) = @_;

        my $x2 = $x + 1;
        my $y2 = $y + 1;
        my $kind;
        $kind = 'oval' if ($form eq 'circle');
        $kind = 'rectangle' if ($form eq 'square');
        $can->create(
            ($kind, "$x" . 'c', "$y" . 'c',
            "$x2" . 'c', "$y2" . 'c'),
            -tags => [$form, $color, $name],
            -fill => $color);
    }

    # This gets the real name (not current, blue/red, square/circle)
    # Note: you'll want to return a list in realistic situations...
    sub get_name {
        my ($can) = @_;
        my $item = $can->find('withtag', 'current');
        my @taglist = $can->gettags($item);
        my $name;
        foreach (@taglist) {
            next if ($_ eq 'current');
            next if ($_ eq 'red' or $_ eq 'blue');
            next if ($_ eq 'square' or $_ eq 'circle');
            $name = $_;
            last;
        }
        return $name;
    }

    sub handle_circle {
        my ($can) = @_;
        my $name = get_name($can);
        print "Action on circle $name...\n";
    }

    sub handle_blue {
        my ($can) = @_;
        my $name = get_name($can);
        print "Action on blue item $name...\n";
    }
[download]

use strict;
use warnings;
use Tk;

my $main = new MainWindow;

my $c = $main->Canvas(
    -width       => 200,
    -height      => 200,
    -relief      => 'sunken',
    -borderwidth => 2,
)->pack(
    -expand => 1,
    -fill   => 'both',
);

$c->CanvasBind( '<1>' => sub {
        my ($c) = @_;
        my $e = $c->XEvent;
        my $x = $c->canvasx( $e->x );
        my $y = $c->canvasy( $e->y );
        print "$x,$y\n";
    }
);

MainLoop;
[download]

And it's better not to use Perl's reserved words for variable names or hash keys, in this case 'ref'.

Thanks! The code does exactly what I'm looking for, guess I was just going about it slightly wrong. And yea, I suppose it's probably best not to use 'ref' to ensure it doesn't cause unexpected weirdness down the road, but it's just so darn convenient! ;)