my @evens = @all[map $_*2+1, 0..$#all/2];
[download]

my @evens = @all[grep !($_ % 2), 0..$#all];    # even-index elements
my @odds  = @all[grep $_ % 2, 0..$#all];       # odd-index  elements
[download]

(update: fixed off-by-one error, in case of uneven number of elements)

$ perl -E 'say grep {++$i %2} <a b c d e f g>'
aceg
$ perl -E 'say grep {$i++ %2} <a b c d e f g>'
bdf
[download]

They only nasty thing about this solution is that it requires a variable (here $i) in the outer scope

A working Perl 6 solution:

$ perl6 -e 'my @a = "a".."g"; say @a[0, *+2 ... +@a]'
aceg
[download]

An idiomatic Perl 6 solution (but not yet implemented in Rakudo):

@a[0, *+2 ... *]
[download]

Another working Perl 6 solution, which is a variation of the grep theme but without the need of an external variable:

say <a b c d e f g>.pairs.grep({.key !% 2})>>.value
[download]

(Updated: Added Perl 6 examples)

With the advent of the new state key word in 5.10. I would think this would be the best solution today.

my @odd  = grep {state $i=1; $i++ % 2}  qw{a 1 b 2 c 3};
my @even = grep {state $i=0; $i++ % 2}  qw{a 1 b 2 c 3};
[download]

Example

perl -e 'use v5.10; my @odd = grep {state $i=1; $i++ % 2}  qw{a 1 b 2 
+c 3}; say @odd;'
[download]

BTW: for one-liners you can use global vars like $a or $b without declaration, even when strict.

C:\>perl -e"print grep {++$a % 2}  qw{a 1 b 2 c 3}"
abc
[download]

Though their values will leak into the outer scope, so state is better for longer scripts.

FWIW: I always thought that an automatic loop-count variable $c or $^c would come very handy inside grep-like constructs.

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

my @all = qw(zero wun two tree fower fife six seven ait niner);
my @evens = @all[grep {not $_ % 2} 0..$#all];
[download]

my @evens = keys %{{@all}};
[download]

Another way to do it:

$ perl -le'
use List::MoreUtils "natatime";
my @x = "a" .. "z";
my $iter = natatime 2, @x;
my @even;
while ( my @y = $iter->() ) {
    push @even, $y[ 0 ];
    }
print "@even";
'
a c e g i k m o q s u w y
[download]

Thanks all!

toolic I didn't know of supersearch so that's useful

cdarke I like the keys approach, hadn't thought of that at all and presumably it's fast, will try that next time if I don't need to preserve order.

For posterity, I decided I actually needed the ODD indices (fwiw, the array has duplicate values in it and I'm porting VBA code which uses 1-based arrays, hence want to keep $all[0] as it = undef) so I used:

@odd = @all[grep($_%2==0, 0..$#all)];

or seomething like that. I guess the not would be faster tho, but I think it'd confuse my readers more, they'll already be struggling with grep, % and $#!!

gah should have said evens - basically edited solution by almac at the top now

my @evens;
{
    last unless @all;
    shift @all;
    last unless @all;
    push @evens, shift @all;
    redo;
}
[download]