Although you could to it with a single pass, I would recommend breaking this into three steps:

1. Read file 1 and store the contents in a hash
2. Read file 2 and store the contents in a second hash
3. Compare the hash keys and output keys that are present in both files

An algorithm for the last step is outlined in a FAQ: How do I compute the difference of two arrays? How do I compute the intersection of two arrays?. I would do something along the lines of:

#!/usr/bin/perl
use strict;
use warnings;

open(my $fh1, '<', "$ARGV[0]") or die "Unable to open $ARGV[0]:$!";
my %hash1;
for (<$fh1>) {
    chomp;
    my ($key,$value) = split /\s+/, $_, 2;
    $hash1{$key} = $value;
}

open(my $fh2, '<', "$ARGV[1]") or die "Unable to open $ARGV[1]:$!";
my %hash2;
for (<$fh2>) {
    chomp;
    my ($key,$value) = split /\s+/, $_, 2;
    $hash2{$key} = $value;
}

for my $key (keys %hash1) {
    next unless exists $hash2{$key};
    print "$key $hash1{$key} $hash2{$key}\n";
}
[download]

Note the addition of '<' to your open statements - this is an important habit to get into for security reasons. Also note that wrapping your input file contents in <code> tags can be just as important as wrapping your code in them.