Cheers,

Brent

This is closely related to some FAQs: How can I tell whether a certain element is contained in a list or array? and How do I compute the difference of two arrays? How do I compute the intersection of two arrays?. The short answer is use a hash:

#!/usr/bin/perl
use strict;
use warnings;

my @array1 = qw(a b c e);
my @array2 = qw(a b c d);

my %hash;
for my $key (@array2) {
    $hash{$key}++;
}

for my $key (@array1) {
    print "Fail: $key\n" unless $hash{$key};
}
[download]

Out of interest using your code as a base how do I print both of the array elements that have caused the mismatch ? e.g.
array1 = "e" array2 = "d"

There are a couple ways to interpret this question. I will assume you mean you would like the elements of each array that are excluded from the union of the two.

#!/usr/bin/perl
use strict;
use warnings;

my @array1 = qw(a b c e);
my @array2 = qw(a b c d);

my %hash;
for my $key (@array2) {
    $hash{$key}++;
}

for my $key (@array1) {
    print "Fail #1: $key\n" unless $hash{$key}--;
}


for my $key (keys %hash) {
    print "Fail #2: $key\n" if $hash{$key} > 0;
}
[download]

For other related solutions, check out How do I compute the difference of two arrays? How do I compute the intersection of two arrays? in perlfaq4

use feature ":5.10"; use strict; use warnings;
my @subset   = qw(a b c e);
my @superset = qw(b a c d x y z);
my $missing = 0;
foreach( @subset ) { $missing++ unless $_ ~~ @superset; }
say "Number missing=$missing";
[download]

Update: Here's another example Symmetric_difference

#!/usr/bin/perl

use strict;
use warnings;

my @a = qw( a b c );
my @b = qw( a b c d );
 
# Get the individual differences.
my @a_minus_b = setminus(\@a, \@b);
my @b_minus_a = setminus(\@b, \@a);
 
# merge then together and remove possible duplicates
my @symmetric_difference = uniq(@a_minus_b, @b_minus_a);
 
# Present our results.
print 'List A: ', join(', ', @a),
"\nList B: ", join(', ', @b),
"\nA \\ B: ", join(', ', @a_minus_b),
"\nB \\ A: ", join(', ', @b_minus_a),
"\nSymmetric difference: ", join(', ', @symmetric_difference), "\n";
 
 
# Takes two array references. Returns a list of elements in the first
# array that aren't in the second.
sub setminus
{
my ($a, $b) = @_;
 
# Convert $b to hash keys, so it's easier to search.
my %b;
@b{@$b} = ();
 
return grep !exists $b{$_}, @$a;
}
 
# take a list and return only uniq items
sub uniq
{
my %saw;
return grep !$saw{$_}++, @_;
}
[download]

I would suggest to use the module Data::Compare. It has more flexible ways to compare other Perl datastructures.

http://search.cpan.org/~dcantrell/Data-Compare-1.22/lib/Data/Compare.pm

i must say, i'm not sure if you were looking for something like this but :

#!/usr/bin/perl

use strict;

my @array_1 = qw(a b r gf s fg h j);
my @array_2 = qw(g d s a b t z nbn df ert uz e ww);

push (@array_2, grep{my $x = $_; not grep{$_ eq $x}@array_2}@array_1);
print "@array_2\n";
[download]

cheers