Yes, almut, I completely missed what you were doing!

Study-up on the web is amazingly difficult on this topic. Source after source discusses "symbol tables" (plural) and forks every other source, contrasting package variables vs lexicals; our vs local vs doing nothing at all; and of course speaking briefly about symbolic references before telling how to use strict so that they can't be used at all. Some sources go into bloody detail about the structure of a typeglob; I even found an interesting explanation of the internal C representation of variables.

There is really (for some value of "really") only one symbol table! Careful reading of Camel tells:

As it happens, the main symbol table contains all other top-level symbol tables, including itself...

I've experimented a bit with this now. Your code works and it's a vast improvement over what I had. This works too, under strict and warnings:

my $ns                  = 'Teddy::';
my $var                 = 'foo';
${ $::{$ns}{$var} }     = 'cheese';
[download]

... which isn't a symbolic reference??

I need to rewrite this entire node. Meanwhile, I bow to almut's superior code-fu.

There is really (for some value of "really") only one symbol table!

Not really — or only if you add "per namespace/package". Somewhat simplified, you can think of it as a nested hash-of-hashes structure. For example, the package(s) Foo::Bar would be represented like

%:: = (
    'Foo::' => {
        'Bar::' => {
            varname => typeglob,
            ...
        },
        ...
    },
    ...
);
[download]

The main difference is that the values associated with the packagename keys like 'Foo::' aren't simple hashrefs, but rather typeglobs, whose hash slot points to the actual symbol table hash. But Perl has some DWIM magic in place for globs, i.e. if you treat it as a hashref, you'll get its hashref entry, which is why you can write $::{'Foo::'}{'Bar::'}{varname}, as if it were a HoHoH.

I need to rewrite this entire node.

Not necessarily  (all I would change is ${*{"${ns}\::foo"}} into the simpler ${"$ns\::foo"} or ${"${ns}::foo"} ).  Symbolic references are there for a reason.  While I would probably use the "non-symbolic" approach for simple static structures like your Teddy:: example, I would rather use symbolic references for more complex/arbitrary structures, (like you might get from caller), because creating a HoHo... access from something variable-depth like Foo::Bar::Baz::... is much too much work compared to locally saying no strict 'refs', and then simply using the string "Foo::Bar::Baz::..." as is...

... which isn't a symbolic reference??

Yes, but it's not any safer than symbolic reference. Given that symbolic references are easier to use, you might as well use those instead of messing with %::.

Compare

my $r = do {
   no strict 'refs';
   \${"${pkg}::$var"}
};
[download]

with

my $r = do {
   $pkg_ref = $r->{$_."::"} for split(/::/, $pkg);
   \($pkg_ref->{$var})
};
[download]

There is a reason why symbolic references exist in Perl, and that is to avoid having to juggle with complex manipulations like yours. Symbolic references is the simple and thus the proper approach for this kind of application.

All you have to do is to locally disable use strict (or at the very least use strict 'refs') by making a small enclosing block, and put

no strict 'refs';
[download]

Even though using direct manipulation of the stashes bypasses strict, that does not imply that it's the better approach.

You just have to know when it is a proper time to break the rules.

having to juggle with complex manipulations like yours

What complex manipulations?  In essence, what I originally suggested as an alternative was

${ $::{$ns}{foo} } = ...
[download]

in place of

{ 
    no strict 'refs';
    ${ "${ns}::foo" } = ...
}
[download]

I fail to see how that is any more complex.  Neither did I say anything about it being "better" in general.

If life was only that simple. Yours is only the simplest case.

Suppose we have a variable $x:

{ 
    package Foo::Bar::Baz;
    our $x = 123;
}
[download]

What is the simplest generic way to get a reference \$x from that package?

$ns = 'Foo::Bar::Baz::';
$ref = \${ $::{$ns}{x} };
[download]

will not work.

You'd have to follow the chain, like this:

$ns = 'Foo::Bar::Baz';
my $stash = \%::;
foreach(split '::', $ns) {
    $stash = $stash->{"$_\::"};
}

$ref = \${ $stash->{x} };
[download]

Or you could use a module like Data::Diver.

All that, just to avoid the use of a symbolic reference:

{
    no strict 'refs';
    $ref = \${ "Foo::Bar::Baz::x" };
}
[download]

Really.

You're going across town through the sewers, just to avoid a few traffic lights.