in reply to Re^2: Printing a tree-view of a hash of hashes
in thread Printing a tree-view of a hash of hashes

The other recursive example goes into an infinite loop.

I presume you mean mine. If so, no it doesn't: 

use strict;
use warnings;

sub print_tree {
   my ($tree, $depth) = @_;
   $depth ||= 0;
   my $indent = '...' x $depth;
   for (sort keys %$tree) {
      print($indent, /^\s*\z/ ? "<blank>" : $_, "\n");
      print_tree($tree->{$_}, $depth+1);
   }      
}

my %categories = (
    level1 => {
        'level1-1' => {},
        'level1-2' => {'level1-2-1' => {}},
        'level1-3' => {},
        },
    level2 => {'level2-1' => {}},
    );


print_tree(\%categories);

[download]
level1
...level1-1
...level1-2
......level1-2-1
...level1-3
level2
...level2-1

[download]

Unless, of course, you don't actually a have tree. Like I said before, %categories doesn't contain what you think it does.

Replies are listed 'Best First'.
Re^4: Printing a tree-view of a hash of hashes
by pdxperl (Sexton) on Jun 01, 2010 at 15:06 UTC
    Thanks -- I didn't mean that comment negatively, as I appreciate the help. Your example is fine with your data, but with mine it did appear to go into infinite recursion. And I agree, there is something odd with what's in the hash, but what I didn't understand was why was is OK in Data::Dumper? So I did track down the cause,which is boiled down to the testcase below. This is what strict was complaining about as the string ref error. I fixed the issue, however, I'm not sure why it causes the tree to be displayed so differently for my approach versus yours versus data dumper. I commented strict out so you can see how the display differs, I know strict normally shouldn't be commented out. Also, this is deliberately showing an error - I'm just showing the odd output that results from that error. 
    #use strict;
use Data::Dumper;

my %h;
$h{'B'}{1}=1; # this is the error which causes the display 
              # issues
for my $a ('A'..'C'){
   for my $b (0..2){
     for my $c ('a'..'c') {
        $h{$a}{$b}{$c}=1; # error if $h{$a}{$b} exists
     }
   }
}
print "Data Dumper-------------------\n";
print Dumper (\%h);
print "Loop----------------\n";
foreach my $top ( sort keys %h){
    if($top =~ /^\s*$/){$top="<blank>";}
    print "$top\n";
    foreach my $second ( sort keys %{$h{$top}}){
       if($second  =~ /^\s*$/){$second="<blank>";}
       print "...$second\n";
       foreach my $third (sort keys %{$h{$top}{$second}}){
        if($third  =~ /^\s*$/){$third="<blank>";}
           print "......$third\n";
       }
    }
}
print "Print_tree------------------\n";
print_tree(\%h);

sub print_tree {
   my ($tree, $depth) = @_;
   if($depth > 5) {
       print "max depth reached\n";
       return;
   }
   $depth ||= 0;
   my $indent = '...' x $depth;
   for (sort keys %$tree) {
      print($indent, /^\s*\z/ ? "<blank>" : $_, "\n");
      print_tree($tree->{$_}, $depth+1);
   }      
}

    [download]
[reply]
[d/l]

      Why is use strict; commented out!? As previously mentioned, this is hiding serious errors. Specifically, you are trying to store both "1" and a hash reference at $h{b}{1}. One simple fix is to use undef instead of 1. 

      use strict;
use warnings;
use Data::Dumper;

my %h;
$h{'B'}{1}=undef;
for my $a ('A'..'C'){
   for my $b (0..2){
     for my $c ('a'..'c') {
        $h{$a}{$b}{$c}=undef;
     }
   }
}
print "Data Dumper-------------------\n";
print Dumper (\%h);

print "Loop----------------\n";
foreach my $top (sort keys %h) {
    print $top =~ /^\s*$/ ? "<blank>" : $top, "\n";
    next if !ref($h{$top});
    foreach my $second (sort keys %{$h{$top}}) {
        print "...", $second =~ /^\s*$/ ? "<blank>" : $second, "\n";
        next if !ref($h{$top}{$second});
        foreach my $third (sort keys %{$h{$top}{$second}}) {
            print "......", $third =~ /^\s*$/ ? "<blank>" : $third, "\
+n";
            next if !ref($h{$top}{$second}{$third});
        }
    }
}

print "Print_tree------------------\n";
print_tree(\%h);

sub print_tree {
    my ($tree, $depth) = @_;
    $depth ||= 0;
    if ($depth > 5) {
        warn "max depth reached\n";
        return;
    }

    my $indent = '...' x $depth;
    for (sort keys %$tree) {
        print($indent, /^\s*\z/ ? "<blank>" : $_, "\n");
        print_tree($tree->{$_}, $depth+1)
            if ref($tree->{$_});
    }
}

      [download]
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom