If you want something in $_, put it in $_.

#!/usr/bin/perl

testy() for 'i am a nice parameter';

sub testy {
   print "$_\n";
}
[download]

I used for to assign in order to $_ to protect the previous value of $_. Clobbering your caller's $_ is a bad idea.

So... $_ here is essentially a global variable the sub is accessing?

yes, $_ is a global variable

Yes, you're accessing the same $_ everywhere. So, by definition, it's a global.

Only, it temporarily gets a new value before the call to your sub, and it gets restored to its old value afterwards.

One way to that yourself is by using

local $_;
[download]

or

local $_ = 'temporary value';
[download]

which makes a copy of your value; or, as ikegami wrote in another reply, using for/foreach:

foreach('temporary value') {
    # your code
}
[download]

which will loop exactly once, with $_ set to an alias of the value (meaning it's a different name for the same value, change the variable and the value will follow (or, for a constant, it might protest against the attempt to change a read-only value).

I'm disturbed because I don't understand how the subroutine used as its first parameter gets $_

The nice thing about open source is that you can take a look at the code, if you want to know how something is being done.  In many cases, an educated guess what keywords to grep for is all that's needed to jump to the right place.  In this case, when you search for $wanted_callback, you find something like this (there are several similar snippets):

    $dir= $p_dir; # $File::Find::dir
    $name= $dir_name; # $File::Find::name
    $_= ($no_chdir ? $dir_name : $dir_rel ); # $_
    # prune may happen here
    $prune= 0;
    { $wanted_callback->() };    # protect against wild "next"
[download]

As you can see, the callback routine is called without argument, but $_ (and other global variables) are populated before the call.

Tutorials -> Beginners guide to File::Find

Localizing $_ is an option, also:

#!/usr/bin/perl

use File::Find;

#find (\&testy, ".");
$_ = 'Main Line...';
testy ('i am a nice parameter');

print "$_\n";

sub testy {

local $_ = shift;  #Localizing it is cool, also.....

print "$_\n" ;

}

__END__

~Output~~
i am a nice parameter
Main Line...
[download]

Good luck. -c

PS: The first parameter passed to a sub is in the first element of the list @_, $_[0], which is NOT the same a $_.

I used for since for and local *_ are more thorough than local $_. One problem case:

for ($tied) {
   ...
   local $_ = 'i am a nice parameter';
   testy();
   ...
}
[download]

No problem:

for ($tied) {
   ...
   local *_;
   $_ = 'i am a nice parameter';
   testy();
   ...
}
[download]

No problem:

for ($tied) {
   ...
   testy() for 'i am a nice parameter';
   ...
}
[download]

Thanks to you all, I get it now (I inadvertently posted anonymously).

I'll check out File::Find::Rule, too.