1. You should indent your code properly so that it is easier to read.
2. You don't need to read the whole file into an array in order to accomplish your task.
3. You don't have to put my in front of every variable name in a list, you just need to put it in front of the left parenthesis for the entire list.
4. You are only using one field ($caseNumber) from each record so there is no need to create variables for the other fields that you are not using.
5. You are defining a subroutine but you never call the subroutine so the code inside it never runs.

You may want something like this (UNTESTED):

#!/usr/bin/perl
use warnings;
use strict;

# open file
my $file = shift @ARGV;
open FILE1, '<', $file or die "Can't open '$file': $!";

my %caseCount;
# Use a while loop to read through the data
while ( <FILE1> ) {
    my $caseNumber = ( split /\t/ )[ 1 ];
    $caseCount{ $caseNumber }++;
}

# close the file you don't need it any more
close FILE1;

#do something here with values in %caseCount
[download]

You missed lecture point #0: use lexical filehandles!

Sorry, I didn't attend that lecture.    :-)

use strict;
use warnings;
use Data::Dumper;

my @data = (
    "o1    n1    a1\n",
    "o2    n2    a2\n",
    "o3    n1    a3\n",
);

my %caseCount;
for my $caseMetrics (@data) {
    my $caseNumber = (split /\t/, $caseMetrics)[1];
    $caseCount{$caseNumber}++;
}

print Dumper(\%caseCount);

__END__

 Output...

$VAR1 = {
          'n2' => 1,
          'n1' => 2
        };
[download]

Since you only seem to use 1 of the columns, just keep the one you want when you split. Splitting into multiple variables is hardly ever a good approach anyway; typically, you would split into an array.

All,

Thanks to everyone for their time and the specific examples. Also, thanks for the greater suggestions regarding formatting of my code, etc. I really appreciate it. You guys are always helpful when I paint myself into a corner, which is often.

I'll dig back into this today.

-Duke

That's what you get for not reading.

You stored it in a variable, which is fine sometimes, but something this straightforward, you don't need to, as said below.

You'll find that there can be some performance impacts when storing whole files into variables, mainly RAM I/O.

As said below, the main culprit why your function isn't doing anything is because you've only defined it, not called it. Adding to jwkrahn's code



#!/usr/bin/perl
use warnings;
use strict;

   main();

   sub main{
      # open file
      my $file = shift @ARGV;
      open FILE1, '<', $file or die "Can't open '$file': $!";

      my %caseCount;
      # Use a while loop to read through the data
      while ( <FILE1> ) {
         my $caseNumber = ( split /\t/ )[ 1 ];
         $caseCount{ $caseNumber }++;
      }
      # close the file you don't need it any more
      close FILE1;

      #do something here with values in %caseCount
      #  DoSomething is an example of how to call a function
      DoSomething(\%caseCount);
   }

   sub DoSomething{
      my $hashref = shift;
      foreach my $key (sort keys %{$hashref}){
         print "$key - ${$hashref}{$key}\n";
      }
   }
[download]

Notice that we've defined a main procedure called "main", which isn't necessary, but it is easier to comprehend for those C programmers. This way, there are no global variables.

We've also shown an example of how to define and call a function, and how to pass a hash as a hash reference and then use it in the sub function/procedure.

Update: because we are using a hashref the extra '$' was necessary in calling the value of for the key: $$hashref{$key}