This would work for Template::HTML, but not for TT2.

Of course it would. You can pass arbitrary perl data structures to TT and its loop controls are better/deeper than HTML::Template's. The reason some people prefer HT over TT is precisely because it has drastically fewer features (and better speed but for the template layer, that's generally the dumbest place to try to optimize) so it is closer to the purist idea of a view; which, as you mention, can be better for the designer, etc. There is nothing HT does that you can't do in TT.

Why don't you post some sample code of what your data structure looks like?

Didn't mean to make it sounds like I'm an advocate for HT over TT2. I recognize the power TT2 provides, and I like what you can do with it. Just wish you could pass it arrays directly from Perl.

My MySQL query looks like this:

# issue query
my $sth = $dbh -> prepare("SELECT uid, fname, lname FROM users") || &b
+ail_out("Error: cannot prepare DB query");
$sth -> execute() || &bail_out("Error: cannot execute DB query");
[download]

The following loop yields an array with all relevant keys and values as individual elements. The results are printed to the terminal for testing:

while (@rray = $sth -> fetchrow_array) {
    $row{uid} = $rray[0];
    $row{fname} = $rray[1];
    $row{lname} = $rray[2];
    push @rows, %row;
}

foreach (@rows) {
    print "$_\n";
}
[download]

This next variation is an attempt to build a hash instead of an array. It only builds one column (lname) from the table at this time. Keys are defined as records.

while (@rray = $sth -> fetchrow_array) {
    $record = "record_$i";
    $hash{$record} = $rray[1];
    $i += 1;
}

my ($key, $value);

while (($key, $value) = each(%hash)) {
    print "key = $key, value = $value\n";
}
[download]

The two pieces of code above work. Finally, however, my attempt to build a HoH is failing. Here is what I have so far:

while (@rray = $sth -> fetchrow_array) {
    $record = "record_$i";
    $hash1{fname} = $rray[1];
    $hash2{$record} = %hash1;
    $i += 1;
}

while (($key, $value) = each(%hash2)) {
    print $hash2{$value} -> {fname};
}
[download]

There are obviously some problems here. Can you offer me some guidance?

Thanks!

$hash1{fname} = $rray[1];
$hash2{$record} = %hash1;
[download]

Values stored in hash entries can only be scalar (not hashes or arrays), so you need to store a reference to a hash, which is scalar.  You get a reference with \

    $hash2{$record} = \%hash1;
[download]

But note that this would store references to the same global hash, in which you'd just overwrite the fname entry for every record.  You most likely want separate hashes, i.e.

    my %hash1;  # new hash instance
    $hash1{fname} = $rray[1];
    $hash2{$record} = \%hash1;
[download]

or simply

    $hash2{$record} = { fname => $rray[1] };
[download]

(the { } create an anonymous hash and return a reference to it)

Here you go. This should be close to what you're doing (adjust the column names in the query). Related reading of interest: DBI recipes.

use warnings;
use strict;
use Template;
use DBI;

my $dbh = DBI->connect("dbi:mysql:mycow;mysql_read_default_file=$ENV{H
+OME}/.my.cnf",
                       undef, undef,
                      { RaiseError => 1 });

my $sth = $dbh->prepare("SELECT id, name, email FROM user LIMIT 3 OFFS
+ET 100");
$sth->execute();
my $employees_loh = $sth->fetchall_arrayref({});

my $tt = Template->new();

$tt->process(\*DATA,
             { users => $employees_loh })
    or die $tt->error(), "\n";

__END__
[% FOR user IN users %]
<div class="record">
  <div class="id">[% user.id %]</div>
  <div class="name">[% user.name %]</div>
  <div class="email">[% user.email %]</div>
</div>
[% END %]

 -- Output ------------------

<div class="record">
  <div class="id">101</div>
  <div class="name">Actaeonis</div>
  <div class="email">Accius@sitesviagra.com</div>
</div>

<div class="record">
  <div class="id">102</div>
  <div class="name">varvang</div>
  <div class="email">vartang@roliks.com</div>
</div>

<div class="record">
  <div class="id">103</div>
  <div class="name">JacobHorony</div>
  <div class="email">jeremilerom@bestbussiness.net</div>
</div>
[download]

I wasn't trying to disrespect HTML::Template too! It's a fine choice and I understand why some prefer a view without a mini-language on top.