#!/usr/bin/perl
use strict;
use warnings;

my $best = {1 =>[1,2]};
my $kept_best = {1 =>[1]};

my $width = 10;
my $precision = 5;

printf "%-${width}s %-${width}s\n", "BEST", "SELECTED BEST";
foreach my $value (sort keys %$best){
    foreach my $bind_energy (@{$best->{$value}}){
        my $kept = shift @{$kept_best->{$value}};
        
        my $format = "\%${width}.${precision}f";
        $format .= defined $kept ? " $format\n" : "\n";

        printf $format, $bind_energy, $kept;
    }
}
[download]

If you find the variable $format approach unclear, you can achieve the same result by just using multiple printfs and an if conditional:

#!/usr/bin/perl
use strict;
use warnings;

my $best = {1 =>[1,2]};
my $kept_best = {1 =>[1]};

my $width = 10;
my $precision = 5;
my $format = "\%${width}.${precision}f ";

printf "%-${width}s %-${width}s\n", "BEST", "SELECTED BEST";
foreach my $value (sort keys %$best){
    foreach my $bind_energy (@{$best->{$value}}){
        printf $format, $bind_energy;
        
        my $kept = shift @{$kept_best->{$value}};
        printf $format, $kept if defined $kept;
        
        print "\n";
    }
}
[download]

TIMTOWTDI.

It took me a few minutes to understand your use of format in the first example, but I love it, very clever.

print "BEST        SELECTED BEST\n";
foreach my $value (sort keys %{$best}) {
    foreach my $i (0 .. $#{$best->{$value}}) {
        printf "%10.5f ", $best     ->{$value}[$i];
        printf "%10.5f" , $kept_best->{$value}[$i]
            if defined    $kept_best->{$value}[$i];
        print "\n";
    }
}
[download]

Yes, the explicit  $i++ was what was really bugging me.

use List::Util qw[ shuffle ];;

%h1 = map{ ("key$_", "value$_" ) } 0 .. 9;;
@selected = (shuffle keys %h1 )[ 0 .. 4 ];;
@h2{ @selected } = @h1{ @selected };;

printf "%-20s %-20s\n", $h1{ $_ }, $h2{ $_ } // '' for sort keys %h1;;
value0               value0
value1               value1
value2               value2
value3
value4               value4
value5
value6               value6
value7
value8
value9
[download]

This looks awesome, but I can't get it to compile.

syntax error at testcode/test.pl line 10, near "@h2{ "
[download]

Too bad I don't have the knowledge base to debug it D:

It works for me. I copy'n'pasted the 5 lines of Perl code, and I am able to reproduce BrowserUk's results without any errors.

Your issue may be related to use strict;. @h2{ @selected } = @h1{ @selected }; uses hash slices to copy values from one hash to another. However, if you simply affix a my, perl will interpret that as a malformed array declaration. If this sounds like your issue, precede the line in question with the statement my %h2;.

Text::Table seems handy.

use strict;
use Text::Table;

my $best = {'key1'=>[1,2,3],'key2'=>['f','g','h'],'el1'=>['y','z','z1'
+]};
my $keep_best = {'key1'=>[4,5], 'el1'=>['w','x'],'key2'=>['i','j','k']
+};

my $table = Text::Table->new("key\n---","BEST\n----","KEEP BEST\n-----
+--");
foreach my $key (sort keys %$best){
 $table->add($key,@{$best->{$key}}[$_],@{$keep_best->{$key}}[$_])
                                                        for (0..$#{$be
+st->{$key}});
        }
print $table;
[download]

key BEST KEEP BEST
--- ---- ---------
el1  y   w
el1  z   x
el1  z1
key1 1   4
key1 2   5
key1 3
key2 f   i
key2 g   j
key2 h   k
[download]