I would suggest a different data structure. You are using a hash of arrays. I would suggest an array of hashes, one for each row. Many times, a parallel set of arrays (HoA) can be better handled as an array of hashes (AoH) with map to pull the requested column.

You can assign the rows using a hash slice or a for loop. You show that you know how to use the loop, so here is a hash slice:

  var %record, @records;
  @record{@colNames} = split(',', $line);
  push @records, \%record;
[download]

To extract data from this structure:

sub total_inventory {
    my $data = shift;
    List::Util::sum(map {$_->{'Inventory'}} @$data);
}
[download]

The data is kept together (shuffling one column will not break the relationships with the rest of the columns).

If you use DBI with one of the CSV modules, you may even be able to use some of the function of an SQL sum() call. When (ok, if) your data moves into a database, you can then migrate with (hopefully) less effort.

chomp(my $line = <IN>);
my @head = split(',', $line);
my @cols;
my $row = 0;
while($line = <IN>) {
  chomp($line);
  my @row = split',', $line;
  $cols[$_][$row] = $row[$_] for 0..$#row;
  $row++;
}
[download]

Hi Sir, In the code what does this IN stands for ?

What about this way (i'm sure it's slowly):

foreach my $header (@headers) {

    push @{ $columns{$header} }, shift @row;
}
[download]

perl -MData::Dumper -e '@header=split ",",<>;while(<>){ @{$AoH[$row++]
+}{@header}=split ",";};print Dumper(\@AoH)' filename
[download]

I realize that this is a learning experience, but you've left out a lot of the complexity of CSVs. Namely, commas are ignored when inside double quoted strings. Basically

only has 3 values. Using split() is only safe once you've looked for quotes. And since this is a chance for you to learn, I'll leave out any hints.

Good luck.

- doug

Never start down the road leading to failure: parse CSV files with split.

Text::CSV_XS and Text::CSV already do your quest in an easy and reliable way:

$ cat test.pl
#!/pro/bin/perl

use strict;
use warnings;
use autodie;
use Text::CSV_XS;

my $csv = Text::CSV_XS->new ({ binary => 1 });
open my $fh, "<", "test.csv";

$csv->column_names ($csv->getline ($fh));
while (my $h = $csv->getline_hr ($fh)) {
    print "$h->{Name} => $h->{Cost}, $h->{Inventory}\n";
    }
$ cat test.csv
Name,Cost,Inventory
pickles,2.99,12
vegemite,4.00,8
nuclear sub,22.50,4
$ perl test.pl
pickles => 2.99, 12
vegemite => 4.00, 8
nuclear sub => 22.50, 4
$
[download]

And with a very small change, your sum's too:

my %sum;
$csv->column_names ($csv->getline ($fh));
while (my $h = $csv->getline_hr ($fh)) {
    print "$h->{Name} => $h->{Cost}, $h->{Inventory}\n";

    no warnings "numeric";
    $sum{$_} += $h->{$_} for $csv->column_names;
    }

print <<EOS;
Total Inventory: $sum{Inventory}
Total Cost:      $sum{Cost}
EOS

=>

pickles => 2.99, 12
vegemite => 4.00, 8
nuclear sub => 22.50, 4
Total Inventory: 24
Total Cost:      29.49
[download]


Enjoy, Have FUN! H.Merijn

The runtime on this isn't horrible, but it is still linear in the number of columns (though not so linear in the number of rows).

Also, considering you are reading in the entire line, you cannot really beat any linearity on the number of columns. In fact, reading in your entire file makes the program at least linear in the size of the data - and considering that each row and each column is represented by at least one character in the data, your running time is at least linear in the product of the number of rows and columns.

Not that this is bad. All I want to point is that being linear in the number of columns is actually very typical for any program reading tabular data.