Re: get the average of hash values?

One way is to store the data in a hash-of-hashes:

use strict;
use warnings;

my %data;
while (<DATA>) {
    chomp;
    my ($id, $value) = split /,/;
    $data{$id}{sum} += $value;
    $data{$id}{count}++;
}

for my $id (sort keys %data) {
    my $avg = $data{$id}{sum}/$data{$id}{count};
    print "$id: sum=$data{$id}{sum} avg=$avg\n";
}

__DATA__
A,10
A,11
A,12
A,13
B,15
B,16
C,17
D,18
[download]

prints:

A: sum=46 avg=11.5
B: sum=31 avg=15.5
C: sum=17 avg=17
D: sum=18 avg=18
[download]

Comment on Re: get the average of hash values? Select or Download Code

Replies are listed 'Best First'.
Re^2: get the average of hash values? by BioLion (Curate) on Jul 28, 2010 at 12:52 UTC
Or you could do a hash of arrays (perldsc) and use List::Util to generate the required results: `use strict; use warnings; use List::Util qw{sum min max}; my %data; while (<DATA>) { chomp; my ($id, $value) = split /,/; push @{ $data{$id} }, $value; # store values as HoA } for my $id (sort keys %data) { print "$id: " . summarise($data{$id}); } sub summarise{ my $arr = shift; return "max=" . max( @$arr ) . " min=" . min( @$arr ) . " sum=" . sum( @$arr ) . " mean=" . ( sum( @$arr )/scalar@$arr ) . "\n"; } __DATA__ A,10 A,11 A,12 A,13 B,15 B,16 C,17 D,18` [download] Gives: `A: max=13 min=10 sum=46 mean=11.5 B: max=16 min=15 sum=31 mean=15.5 C: max=17 min=17 sum=17 mean=17 D: max=18 min=18 sum=18 mean=18` [download] NB: Code pretty much exactly the same as toolic's post... Just wanted to show TIMTOWTDI! Just a something something...	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: get the average of hash values?
by BioLion (Curate) on Jul 28, 2010 at 12:52 UTC

Or you could do a hash of arrays (perldsc) and use List::Util to generate the required results:

use strict;
use warnings;
use List::Util qw{sum min max};

my %data;
while (<DATA>) {
    chomp;
    my ($id, $value) = split /,/;
    push @{ $data{$id} }, $value; # store values as HoA
}

for my $id (sort keys %data) {
    print "$id:  " . summarise($data{$id});
}

sub summarise{
    my $arr = shift;
    return "max=" . max( @$arr ) 
        . " min=" . min( @$arr ) 
            . " sum=" . sum( @$arr ) 
                . " mean=" . ( sum( @$arr )/scalar@$arr ) 
                    . "\n";
}
__DATA__
A,10
A,11
A,12
A,13
B,15
B,16
C,17
D,18
[download]

Gives:

A:  max=13 min=10 sum=46 mean=11.5
B:  max=16 min=15 sum=31 mean=15.5
C:  max=17 min=17 sum=17 mean=17
D:  max=18 min=18 sum=18 mean=18
[download]

NB: Code pretty much exactly the same as toolic's post... Just wanted to show TIMTOWTDI!

Just a something something...

[reply]
[d/l]
[select]