Unexpected Output

k_manimuthu has asked for the wisdom of the Perl Monks concerning the following question:

Hi Monks,

I need to assign $string = 'some values' based on the length of the array. If length of the array equals to '-1' I want to assign $string = 'True', otherwise I expect $string = 'False'.

I got $string = 'False' even though the array values is equals to '-1'. But i am add a line to test the array value, I got the output as 'True'. I am confused, why the code's gives the mismatch output.

Below I placed the code. Could someone please explain on this.

Thanks
Mani Muthu

use strict;
use warnings;

my @arr;
my $string = 'Initial';

($#arr == -1 ) ? print "True" : print "False";
($#arr == -1 ) ? $string = 'True' : $string = 'False';

print "\n\$string  = $string";
print "\n\$#arr    = $#arr";


=Output
True
$string  = False
$#arr    = -1
=cut
[download]

Note : I am using perl 5.8.9 in Windows

Comment on Unexpected Output Download Code

Replies are listed 'Best First'.
Re: Unexpected Output by cdarke (Prior) on Jul 28, 2010 at 08:22 UTC
This is a precedence problem with your ternary statement. If you parenthesise: `($#arr == -1 ) ? ($string = 'True' ): ($string = 'False');` [download] then the output is as expected. However it is probably better written as: `$string = ($#arr == -1 ) ? 'True' : 'False';` [download] By the way, `$#arr` is not the length of the array, it is the highest index number. So your ternary could be written like this: `$string = @arr ? 'False' : 'True';` [download] The array in scalar context gives the number of elements (zero is false).	[reply] [d/l] [select]
Re: Unexpected Output by moritz (Cardinal) on Jul 28, 2010 at 08:15 UTC
The problem is that the assignment operator has looser precedence than the ternary/conditional operator `? :`. Instead, use `$string = $#arr == -1 ? 'True' : 'False';` [download] If you want to assign to two different variables, use an ordinary `if` construct instead of the ternary operator. Perl 6 - links to (nearly) everything that is Perl 6.	[reply] [d/l] [select]
Re: Unexpected Output by Corion (Patriarch) on Jul 28, 2010 at 08:17 UTC
If you only want to check whether an array is empty, it's nicer to use `if (@arr) { ... };` [download]	[reply] [d/l]
Re: Unexpected Output by nvivek (Vicar) on Jul 28, 2010 at 11:41 UTC
For checking the length of an array,don't use $#arrayname because it won't give the number of elements in an array and it gives the highest index of the array which is number of elements - 1 in the array.If you want to check the length of an array, you assign an array to scalar, then it will give the actual number of elements in the array.There is one more problem in $#arrayname, it gives the value by adding the value of $[ with highest index of an array.In your script, if you change the value of $[ variable, then $#arrayname won't give the correct value.	[reply]
Re: Unexpected Output by Khen1950fx (Canon) on Jul 28, 2010 at 08:33 UTC
I added some parentheses...Still a little messy, but it works. `#!/usr/bin/perl use strict; use warnings; my @arr; my $string = 'Initial'; ($#arr == -1 ) ? print('True') : print ('False'); ($#arr == -1 ) ? ($string = 'True') : ($string = 'False'); print "\n\$string = $string"; print "\n\$#arr = $#arr\n";` [download]	[reply] [d/l]
Re: Unexpected Output by Your Mother (Archbishop) on Jul 28, 2010 at 16:21 UTC
Please use the `$string = @arr ? 'False' : 'True';` idiom cdarke offered. `$#arr` is (so I say) a poor style choice to use anywhere (in general) and both confusing and potentially error prone here (as nvivek notes).	[reply] [d/l] [select]
Re^2: Unexpected Output by k_manimuthu (Monk) on Jul 29, 2010 at 07:26 UTC
Dear All - Thanks a lot for your suggestion and solutions. Thanks to introduce some new things to me. Specially for ... `$string = ($#arr == -1 ) ? 'True' : 'False';` [download]	[reply] [d/l]