Open the two files, then read a line from each file on every iteration:

while (my $col1 = <FILE1>) {
    chomp $col1;
    my $col2 = <FILE2>;
    print "$col1\t$col2";
}
[download]

Ooooh, that's nice, I had no idea perl could do that. This is the sort of thing I was looking for.

One issue, though: it seems to choke if the two files don't have the same number of lines. I could just count the lines in each and pad the shorter file with as many \n as required before starting the loop, but there has to be a better solution than that. Any tips?

while (my $col1 = <FILE1>) {
    chomp $col1;
    last unless (my $col2 = <FILE2>);
    print "$col1\t$col2";
}
[download]

the above will stop at the end of the shorter file
print "Good ",qw(night morning afternoon evening)[(localtime)[2]/6]," fellow monks."

elef:

For elegant and efficient, I'd go with (on a *NIX box):

In perl, I'd use the code in Re: parallel reading.

...roboticus

#! perl -slw
use strict;

open ONE, '<', $ARGV[0] or die $!;
open TWO, '<', $ARGV[1] or die $!;

until( eof( ONE ) ) {
    chomp( my $one = <ONE> );
    chomp( my $two = <TWO> );
    print "$one\t$two";
}

close ONE; close TWO;

__END__
c:\test>junk11 file1 file2
one     1
two     2
three   3
four    4
five    5
six     6
seven   7
eight   8
nine    9
ten     10
[download]

I consider the file1 and the file2 contents are equal numbers

use strict;
use warnings;

### open the first file and store in to a array format
open (F1, "file1.txt") || die "Cannot open the input file : $!";
my @file1=<F1>;
close (F1);

### open the second file and store in to a array format
open (F2, "file2.txt") || die "Cannot open the input file : $!";
my @file2=<F2>;
close (F2);

my @file3;
### process each element and store the file1 and the corresponding
### value in second file in another one array
for (my $i=0; $i<=$#file1; $i++)
{
    chomp($file1[$i]);
    push @file3, "$file1[$i]\t$file2[$i]";
}

### print the array in a output file
open (FOUT, ">Concat.txt") || die "Cannot create the output file";
print FOUT @file3;
close (FOUT);
[download]

You could also look at the Tie::File module, which allows you to access a file as an array. Here is some sample code:

#!perl
use strict;
use warnings;
use feature qw(:5.10);

use Tie::File;

tie my @file1, 'Tie::File', 'file1' or die "Cannot tie file1: $!";
tie my @file2, 'Tie::File', 'file2' or die "Cannot tie file2: $!";

foreach(0 .. $#file1){
    say "$file1[$_]\t$file2[$_]";
}

untie @file1;
untie @file2;
[download]

You may have to do some error checking if you expect the files to be different lengths.

Update: Link fixed.

Thanks for that one, I'll keep it in mind. It seems that, despite what one might assume, Tie::File is part of the standard perl distribution and it doesn't read the whole file into memory. It should be come in pretty handy.

use strict;
use autodie;

open my $one, "<", "data1";
open my $two, "<", "data2";

{
    my $line1 = <$one>;
    my $line2 = <$two>;
    last unless $line1 or $line2;
    chomp $line1;
    chomp $line2;
    print "$line1\t$line2\n";
    redo;
}
[download]

awk 'NR==FNR{a[NR]=$0;next}{a[FNR]=a[FNR]"\t"$0}END{for(x=1;x<=FNR;x++
+){print a[x]}}' file1 file2
[download]