Try HList, just put the code below to open in a new toplevel, or frame. Also check out a wacky widget I made at Tk-CanvasDirTree, which is a dynamic tree on a canvas. In the below example, you would put the HLists into a Scrolled::Pane, but this simple example just dumps them adjacent to the last in a simple Frame.

#!/usr/bin/perl
use strict;
use Tk;
use Tk::HList;

my $mw = MainWindow->new();

$mw->geometry("500x500+100+100");

my $h;

#create some sample data
my %data;

foreach (0..100) {
      $data{$_}{'name'} = 'name'.$_;
      $data{$_}{'id'} =   rand(time);
     }
#get random list of keys
my @keys = keys %data; 

#################


my $button0 = $mw->Button(-text => 'show list',
                         -command => sub{ showlist() } )->pack;


my $button = $mw->Button(-text => 'exit',
                         -command => sub{exit})->pack;

my $sortid = $mw->Button(-text => 'Sort by Id',
                         -command => [\&sort_me,1] )->pack;


MainLoop;
#########################################################


sub showlist{

$h = $mw->Scrolled( 'HList', 
                       -header => 1,
                       -columns => 2,
                       -width => 30,
                       -height => 60,
                       -takefocus => 1,
                       -background => 'steelblue',
                   -foreground =>'snow',
               -selectmode => 'single',
                       -selectforeground => 'pink',
                       -selectbackground => 'black',
                #       -browsecmd => \&browseThis,
                   )->pack(-side => "left", -anchor => "n");

my $nameh = $h->header('create', 0, -text => '   Name  ',
                        -borderwidth => 3,
                        -headerbackground => 'steelblue',
            -relief => 'raised');

my $idh = $h->header('create', 1, -text => '      ID      ',
                        -borderwidth => 3,
                        -headerbackground => 'lightsteelblue',
                    -relief => 'raised');


foreach (@keys) {
     my $e = $h->addchild(""); #will add at end
        
     $h->itemCreate ($e, 0,
           -itemtype => 'text',
           -text => $data{$_}{'name'},
            );
                        
     $h->itemCreate($e, 1,
           -itemtype => 'text',
           -text => $data{$_}{'id'},
         );

}

}




sub sort_me{
  my $col = shift;

  my @entries = $h->info('children');
  my @to_be_sorted =();

 foreach my $entry(@entries){
           push @to_be_sorted,
       [ $h->itemCget($entry,0,'text'),
         $h->itemCget($entry,1,'text')
       ];
           }

  my @sorted = sort{ $a->[$col] cmp $b->[$col] } @to_be_sorted;
            
my $entry = 0;
  foreach my $aref (@sorted){
#    print $aref->[0],' ',$aref->[1],"\n";
    $h->itemConfigure( $entry, 0, 'text' => $aref->[0] );  
    $h->itemConfigure( $entry, 1, 'text' => $aref->[1] ); 
    $entry++;
  }

$mw->update;
}
[download]