Storable freeze produces a binary string that may contain a whole bunch of characters that would be incompatible with passing as part of a url. You might try url encoding the results of freeze, but I wouldn't like to rely upon that.

It would be better to hexify the frozen data before adding it as a part of your url.

Given oneScript like this:

#! perl -slw
use strict;
use Storable qw[ freeze ];

my %params = (
   period => 30,
   vid => 'xyz1234',
   person => 'homer',
);

my $encoded = unpack 'H*', freeze \%params;

system qq[otherScript.pl ?arg=$encoded];
[download]

Calling another script like this:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];
use Storable qw[ thaw ];

my( $name, $payload ) = split '=', $ARGV[ 0 ];

my $params = thaw pack 'H*', $payload;

pp $params;
[download]

The result is:

c:\test>oneScript
{ period => 30, person => "homer", vid => "xyz1234" }
[download]

use URI qw( );
sub url_freeze {
   my ($base_url, @args) = @_;
   return URI->new($base_url, 'http')->query_form(@args);
}

my $url = url_freeze('/cgi-bin/details', %args);
[download]

I may have the exact usage a bit off.

Usage is more like this:

use URI;
use strict;
use warnings;
my $hostname = 'localhost';
my $path = '/cgi-bin/details';
my $period = 4;
my $vid = 11;
my $person = 'abcdef';
my @args = ( period => $period, 
             vid    => $vid,
             person => $person );
my $url = URI->new("http://$hostname/");
$url->path($path);
$url->query_form( \@args );
print $url->canonical;
[download]

The URI accessors do not support chaining.

Update: I misread the parent as using chained accessors, which it wasn't, this is just a little more verbose than that

You changed

->query_form(@args);
[download]

to

->query_form(\@args);
[download]

but both are ok. So that leaves the bad return value. Fixed:

use URI qw( );
sub url_freeze {
   my $url = URI->new(shift, 'http');
   $url->query_form(@_);
   return $url
}

my $url = url_freeze('/cgi-bin/details', %args);
[download]

It won't freeze recursively, of course.

Please read How (Not) To Ask A Question, and then ask your question again, this time providing enough information for us to actually answer it.

Like most others I'm confused by what you are trying to ask for. Are you looking for something like CGI::Session?