@{$h{CUST}} is an array of hash references. Just take each hash reference and de-reference the NAME parameter.

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my %h;

push @{$h{CUST}},  {
                       NAME       => 'Mr.y',
                       ADD        => 'Hell',
                   };
                           
push @{$h{CUST}},   {
                       NAME       => 'Mr.z',
                       ADD        => 'Hell',
                    };
                           

push @{$h{ADMIN}},  {  NAME       => 'Mr.x',
                       ADD        => 'Hell',
                    };
                           

print Dumper \%h;

foreach my $href  ( @{$h{CUST}})
{
   print " CUST NAME: $href->{NAME} \n";
}

__END__
$VAR1 = {
          'ADMIN' => [
                       {
                         'NAME' => 'Mr.x',
                         'ADD' => 'Hell'
                       }
                     ],
          'CUST' => [
                      {
                        'NAME' => 'Mr.y',
                        'ADD' => 'Hell'
                      },
                      {
                        'NAME' => 'Mr.z',
                        'ADD' => 'Hell'
                      }
                    ]
        };
 CUST NAME: Mr.y 
 CUST NAME: Mr.z
[download]

#one way for initial structure
foreach my $aref  ( @{$h{CUST}})
{
   print " CUST NAME: $aref->[0]->{NAME} \n";
}

#another way for initial structure
foreach my $href  (map{$_->[0]} @{$h{CUST}})
{
   print " CUST NAME: $href->{NAME} \n";
}
[download]

use strict;
use warnings;

my %h;

push @{$h{CUST}},
                            {
                              NAME       => 'Mr.y',
                              ADD        => 'Hell',
                            }
                           ;
push @{$h{CUST}},
                            {
                              NAME       => 'Mr.z',
                              ADD        => 'Hell',
                            }
                           ;
push @{$h{ADMIN}},
                            {
                              NAME       => 'Mr.x',
                              ADD        => 'Hell',
                            }
                           ;
my $val = $h{CUST};
for my $href (@{ $val }) {
    print "$href->{NAME}\n";
}

__END__

Mr.y
Mr.z
[download]

What they said.

But also, you're using commas in your C-style loop, where the correct delimiter is semi-colons. Without semi-colons, it's being interpreted as some non-C-ish for-loop, where you want to run three commands in sequence: $i, $i<@$val, and $i++, ( the first two presumably for side-effects) and use the value of the third.

I haven't used a C-ish loop in years ... not relevant in Perl. If you DO want to increment over the indices, the simplest way is using the range operator:

for my $index ( 0 .. @{$val} -1 ) {
   do_stuff()
}
[download]

But mostly for loops are for iterating over arrays or lists, possibly the keys from hashes

By the way, if you want to initialize data structures, you can do it directly, you don't need to push values on. But maybe you were just doing that since you weren't getting output, and worried it might be something about the initialization. You clearly have a handle on anonymous arrays and hashes.

my %h = ( CUST => [ { NAME => 'Mr. y', ADD => 'Hell' },
                    { NAME => 'Mr. z', ADD => 'Dell' },
                  ],
          ADMIN => [ {  NAME > 'Mr. x', ADD => 'Hell' },
                   ],
        );
[download]

I use trailing commas and leave the closing brace on the next line, to make it easier to add more entries.