If you live in a non-unicode world, then tr///was designed for this:

$s = 'This is A mIxEd-Case STRING';;
$s =~ tr[A-Za-z][a-zA-Z];;

print $s;;
tHIS IS a MiXeD-cASE string
[download]

What did you try so far? At which point did you fail? Have you looked at the functions uc and lc?

The code i could think of

if ($string =~ /[A-Z]+/){
        $string = lc $string;
}else{
        $string = uc $string;
}
[download]

Your code lower-cases the whole string if a singe uppercase character is found. Is that what you want? What should happen to strings with mixed case?

Also you ignore all non-ASCII upper case letters.

Perl 6 - links to (nearly) everything that is Perl 6.

How do is the case of a string identified?

For a letter you can use the regex /\p{Lu}/ which matches upper case letters, \p{Ll} for lower case, and \p{Lt} for title case. Also remember that many characters don't have the lower case/upper case distinction (like digits, and letters from many different writing systems).

A crude way would also be a test like lc($x) eq $x

$ perl -le'$_ = "MiXeD CaSe ExAmPlE"; print; s/([[:alpha:]])/ $1 eq "\
+U$1" ? "\L$1" : "\U$1" /eg; print'
MiXeD CaSe ExAmPlE
mIxEd cAsE eXaMpLe
[download]

/usr/bin/perl

use strict;
use warnings;
use Text::Autoformat;

my $formatted = autoformat 'WHAT DO YOU WANT RETURNED', 
{ case => 'lower' };
print $formatted;

my $formatted1 = autoformat 'what do you want returned', 
{ case => 'upper' };
print $formatted1;
[download]

Text::Autoformat looks pretty cool but it seems like overkill compared to uc and lc.

The use cases in my case are that the string will either be entirely in upper case of lowercase.

Apologies for not mentioning this earlier.

In that case:

my $reversed = $str =~ /\p{Lu}/ ? lc $str : uc $str;  # Or
my ($reversed) = map {/\p{Lu}/ ? lc : uc} $str;
[download]

Following code will help you.

use strict;
use warnings;

print "Enter the string:";
my $string=<STDIN>; #getting the input from user
 
chomp($string); #remove the newline at end in string

if($string=~/^[a-z]+$/) { #checking whether the string is in lowercase
print "String given in Lower Case:$string\n";
$string=~s/([a-z])/\u$1/g; #replacing the string to be in upper case
print "Uppercase String:$string\n";
}
elsif($string=~/^[A-Z]+$/) { #checking whether the string is in upperc
+ase
print "String given  in Upper Case:$string\n";
$string=~s/([A-Z])/\l$1/g; #replacing the string to be in lower case
print "Lowercase String:$string\n";
}
elsif($string=~/^[a-zA-Z]+$/) { #checking whether the string is in mix
+ed case
print "String given in Mixed Case:$string\n";
$string=~s/([a-z])/\u$1/g; #replacing the string to be in upper case
print "Uppercase String:$string\n";
$string=~s/([A-Z])/\l$1/g; #replacing the string to be in lower case
print "Lowercase String:$string\n";
}
[download]

Your mixed case test will not work the way you intended

/[a-zA-Z]/ matches any lower- or uppercase character, not a lower- and then an uppercase one.

And your two substitutions will not flip the case of a character because after the first substitution (i.e. s/([a-z])/\u$1/g) all characters are uppercase and will be changed to lowercase at the second substitution.