Quoth perlre (see section on Capture buffers):

The numbered match variables ($1, $2, $3, etc.) and the related punctuation set ($+, $&, $`, $', and $^N) are all dynamically scoped until the end of the enclosing block or until the next successful match, whichever comes first. (See "Compound Statements" in perlsyn.)

Update: Try this with and without the  { } block enclosing the substitution statement (Update: changed example code to try to clarify the point a bit):

>perl -wMstrict -le
"my $line = 'One two three four five';
 if ($line =~ m/(one)\s(two)\s(three)\s(four)\s(five)/i){
   my $neo;
   { ($neo = $1) =~ s{ (o)(ne) }{$2$1}xmsi; }
   print qq{neo '$neo'};
   print qq{1: $1};  print qq{2: $2};  print qq{3: $3};
   print qq{4: $4};  print qq{5: $5};
   }
"
neo 'neO'
1: One
2: two
3: three
4: four
5: five
[download]

my $line = "One two three four five";
if (my @captures = $line =~ m/(one)\s(two)\s(three)\s(four)\s(five)/i)
+ {
   $captures[0] =~ s/one/ONE/i;
   print "$_: $captures[$_-1]\n" for 1..5;
}
[download]

Note that uc might be more appropriate here. Any maybe split.

my $line = "One two three four five";
if (my @captures = split(' ', $line)) {
   $captures[0] = uc($captures[0]);
   print "$_: $captures[$_-1]\n" for 1..5;
}
[download]

Thank you, every one who took the time to answer this. The exercise of writing the request resulted in my realizing when I awoke this AM that the $1, etc involved the most recent match BUT the explanations you provided are instructive beyond the answer to my query and I have learned something that will further improve my program.

The numbered match variables ($1, $2, $3, etc.) and the related punctuation set ($+ , $& , $` , $' , and $^N ) are all dynamically scoped until the end of the enclosing block or until the next successful match, whichever comes first.

If the match had failed, and the substitution had not been performed, the match variables retain their values:

my $line="One two three four five";
if($line =~ m/(one)\s(two)\s(three)\s(four)\s(five)/i){
 my $one=$1;
 $one =~ s/ten/ONE/i;   #  <--- no match
 print "1: $one\n";
 print "2: $2\n";
 print "3: $3\n";
 print "4: $4\n";
 print "5: $5\n";
}#if

__END__

1: One
2: two
3: three
4: four
5: five
[download]

As other people have noted, a subsequent successful match resets the captured values. However, this doesn't have to create a problem; you can use the list behavior of captures in a regex to save them for reuse.

#!/usr/bin/perl -w
use strict;

my $line="One two three four five";
my @chunks;
if(@chunks = $line =~ m/(one)\s(two)\s(three)\s(four)\s(five)/i){
    $chunks[0] =~ s/One/ONE/;   # Change the first chunk
    $chunks[1] =~ s/two/tWo/;   # Change the second chunk
    # ...
}
print "@chunks\n";
[download]

Output:

ONE tWo three four five
[download]

Absolutely - I can't emphasize enough how important it is to get in the habit of explicitly capturing your matches. It's easy to get lazy about using the values right away, and then your program develops mysterious bugs when someone else adds a "harmless" function call that invokes something else that internally does a pattern match, but only sometimes...

I also recommend getting into the habit of naming your captures; that way it's much clearer: "now does $capture[4] contain the right value, or was it $capture[3]?". If you do this:

my($name, $age, $weight) = ($line =~ /$pattern/);
[download]

you'll be much less likely to set someone's age to 180 and their weight to 40.