use strict; 
use warnings; 

my $s = ' A ||118|AVIANN GILDED WILD HONEY. HM 75081701. 02-04-97';
if ($s =~ / ^ .* [|] (.*) [.] ([^.]+) [.] ([^.]+) $ /x) {
    my $name = $1;
    my $num  = $2;
    my $date = $3;
    print "Name = $name\n";
    print "Num  = $num\n";
    print "Date = $date\n";
}

__END__

Name = AVIANN GILDED WILD HONEY
Num  =  HM 75081701
Date =  02-04-97
[download]

Can you show a few more lines of your actual input?

Update: The above now accounts for a period in the name. Here is my original code:

if ($s =~ / .* [|] ([^.]+) [.] ([^.]+) [.] (.*) /x) {
[download]

When crafting regular expressions, it helps to build off of the more stable parts of the input. In this case, it sounds like there is a ton of variability in the initial and middle parts of the input, but not so much at the end.

I started from the end.

perlpie$ perl -e '
    print "A ||118|AVIANN GILDED WILD HONEY. HM 75081701. 02-04-97"
        =~ /.+?\.\s+(.+)\.\s+[-\d]+$/
        ? "id is [$1]\n"
        : "id not found\n";
'
id is [HM 75081701]
[download]

From the end, there's the $ to anchor at the tail, then the \s+[-\d] to gobble up the date of birth, then \.\s+ to get the period and whitespace, then the capture which I've made *very* liberal (.+) and then the period space which precedes it \.\s+ and at the very start a non-greedy .+? to slowly move through the input until the rest of the pattern can match.

Now you could fool that pretty easily. Just stick a dot space in the dog's name and the bit preceding the match will match too soon and you'll get too much in the ID.

perlpie$ perl -e '
    print "A ||118|AVIAN. GILDED WILD HONEY. HM 75081701. 02-04-97"
        =~ /.+?\.\s+(.+)\.\s+[-\d]+$/
        ? "id is [$1]\n"
        : "id not found\n";
'
id is [GILDED WILD HONEY. HM 75081701]
[download]

So, we need to be a bit more rigid about the ID.

perlpie$ perl -e '
    print "A ||118|AVIAN. GILDED WILD HONEY. HM 75081701. 02-04-97"
        =~ /.+?\.\s+(\w\w(?:\s+|--)\d+)\.\s+[-\d]+$/
        ? "id is [$1]\n"
        : "id not found\n";
'
id is [HM 75081701]
[download]

That works. We're now using \w\w(?:\s+|--)\d+ which matches two word characters followed by (non-capturing parens to contain the alternation) either whitespace or double-dash followed by digits. You can try it with hyphens and the wrong number of digits and a decoy id in the dog's name:

perlpie$ perl -e '
    print "A ||118|AVIAN. GILDED WILD HONEY. HM 1234567. HM--75081. 02
+-04-97"
        =~ /.+?\.\s+(\w\w(?:\s+|--)\d+)\.\s+[-\d]+$/
        ? "id is [$1]\n"
        : "id not found\n";
'
id is [HM--75081]
[download]

If you wanted, you could get even more strict about the ID. You could also clean up the id to replace double-hypens with spaces before you do anything else with it.

For more info on perl regular expressions, you'll want to check out perlre.

my @lines = (
   "  A \t\t118\tAVIANN GILDED WILD HONEY. HM 123456. 02-04-97  \n",
   "  A \t\t118\tAVIANN-GILDED ... 'WILD' & HONEY. HP--09090901. 02-04
+-97  \n",
);

for my $line (@lines)
{
    my ($name, $reg, $dob) = ($line =~ /
        ^.+\t                             # ignore everything till the
+ last tab
        (.+?)                             # capture dog name
        \s+
        ([[:alpha:]]{2} [-\s]{1,2} \d+)\.? # capture dog registration
        \s+
        (\d{2}-\d{2}-\d{2})               # capture DOB
        \s*$                              # anchor the end of regexp
    /x);
    
    print
      "Name : $name\n",
      "Reg  : $reg\n",
      "DOB  : $dob\n\n";
}

__END__
Name : AVIANN GILDED WILD HONEY.
Reg  : HM 123456
DOB  : 02-04-97

Name : AVIANN-GILDED ... 'WILD' & HONEY.
Reg  : HP--09090901
DOB  : 02-04-97
[download]

TIMTOWTDI

if ( $dog =~ /[^|]*\|[^|]*\|[^|]*\|([A-Z ]*)\.\s([A-Z]{2})\s(\d{6,8})\
+.\s(\d{2}-\d{2}-\d{2})/ ) {
    my $name = $1;
    my $id = $2 . $3;
    my $dob = $4;
[download]

Three repeats of "anything not a pipe followed by a pipe"; capture the name; period; space; capture the two leading letters in the ID; space; capture 6 to 8 digits (see explanation above of unix vs perl handling of the numeric quantifier range); period, space; capture dob.

I'm confused: at one point you state that the id may contain 6 to 8 (inclusive) digits but later write that you wish to allow 6-9 digits. Is that because sometimes a 9-digit id is "legal"?

Arguably ugly; also arguably "(painfully) clear."

Dealing with the permissable alternate characters in the name and with alternate (typo) hyphens in the id (hint: "quantifiers" and "alternation") left as an exercise for the OP.

My approach below. If split could work starting from right to left instead of the other way round, I'd use it! But alas it doesn't do that! Below I worked from right to left and used \S (non-space) and \s (space) Perl short-cuts. I think it is fine to use a combination of "fixing" and regex "splitting". In the case as explained so far, it is certainly possible to do everything in one regex. But, you've already seen the value in changing the tabs to | characters so that you can see them and print. Sometimes these intermediate steps work out to be real handy for debugging!

#!/usr/bin/perl -w
use strict;

my @tests = (
   'A ||118|AVIANN GILDED WILD HONEY. HM 75081701. 02-04-97',
   'A ||118|||AVIANN GILDED &^$WILD HONEY HP--09090901. 02-04-97',
);


foreach my $test (@tests)
{
   $test =~ s/^.*\|//; #remove beginning til last |
                    
   #"fix" possible typo in the registration number
   #  HP--09090901. becomes HP  09090901.  

   $test =~ s/(\w+)[-]+([\d.]+\s+\S+)$/$1 $2/; 
                             
   my ($name,$number,$date) = $test =~ m/^(.*)\s+(\S+\s+\S+)\s+(\S+)$/
+;
   $number =~s/\.$//;  #fix possible typo trailing '.'

   print "\n name=$name\n number=$number\n date=$date\n";
} 

__END__
name=AVIANN GILDED WILD HONEY.
number=HM 75081701
date=02-04-97

name=AVIANN GILDED &^$WILD HONEY
number=HP 09090901
date=02-04-97
[download]