Given your very vague specifications, I would very strongly consider using completely separate programs. Both, fork and threads will consume many resources and make debugging your program very hard.

As you need to perform very different tasks (connect via ssh, connect via DBI, ...), putting all the code for these different tasks into one program makes little sense.

Have one central program that starts the specific programs as separate children. Consider maybe Parallel::Jobs or simple open "$child |" to run your child processes in parallel.

But before thinking about how to do things in parallel, I really, really urge you to first get things working in a serial fashion.

Thanks for response.
For ssh and DBI we will have two separate programs, and will be easy to maintain. for running in sequential, we will have problem.
Example: there is poosility of delay in process for few servers and might create problem when report won't be available on time.
I am thinking to use Thread::queue, will divide servers into 10-15 groups and kick off programm with GRP1..N as input parameter.
example:
1. collector. pl GRP1 ## GRP1 will contain 30-40 dataserver
Please suggest if this approach is not efficient.
Thanks

Here's a very basic skeleton that will serve as a basis for you to tweak to do the job. It uses a prioritising subclass of Thread::Queue to 'schedule' the repeat jobs:

#! perl -slw
use strict;
use threads;
use Thread::Queue;
use LWP::Simple;

{
    package T::Q::O;
    use Data::Dump qw[ pp ];
    require Thread::Queue;
    use threads;
    use threads::shared;
    our @ISA = 'Thread::Queue';

    sub enqueue {
        local $^W;
        my $Q = shift;
        lock @$Q;
        for( @_ ) {
            push @$Q, $_;
            my $n = $#$Q;
            @{ $Q }[ $n, $n-1 ] = @{ $Q }[ $n-1, $n ], --$n
                while $n-1 and $Q->[ $n ] < $Q->[ $n - 1 ];
        }
        cond_signal( @$Q );
    }

    sub dump {
        my $Q = shift;
        lock @$Q;
        pp $Q;
        cond_signal( @$Q );
    }
}

sub dbiFetch {
   my @args = @_;
   return getstore $args[ 0 ], 'nul';
}

sub sshFetch {
   my @args = @_;
   return getstore $args[ 0 ], 'nul';
}

sub tcpFetch {
   my @args = @_;
   return getstore $args[ 0 ], 'nul';
}

sub worker {
    no strict 'refs';
    my $Q = shift;

    while( my $work = $Q->dequeue ) {
        my( $time, $interval, $sub, @args ) = split $;, $work;
        sleep 1 while time() < $time;
#        printf "now: %.f time:$time int:$interval sub:$sub [@args]", 
+time();
        my $result = $sub->( @args );
#        print $result;
        $Q->enqueue( join $;, $time + $interval, $interval, $sub, @arg
+s );
    }
}

our $W //= 10;

my $Q = new T::Q::O;

my @workers = map async( \&worker, $Q ), 1 .. $W;

while( <> ) {
    chomp;
    $Q->enqueue( join $;,
        time(), (map $_*60, 1,2,3 )[ rand 3 ],
        ( qw[dbiFetch sshFetch tcpFetch ] )[ rand 3 ],
        $_
    );
}

1 while sleep 1;
[download]

Thanks a lot for response, going to develop one basic module for one group of dataservers(30-40), which will have only DBI connection. Above code will be helpful to start. Will post my code once I done.
Thanks