Sort hash keys

kalyanrajsista has asked for the wisdom of the Perl Monks concerning the following question:

Monks

I'm trying to sort the hash based on their keys and key is inform of some 'UniqueNumber-Sequence'. Here is what I tried.... Output should be like

1035-46
1035-65
1035-2341
1035-2347
[download]

#!/usr/bin/perl

my %seq = ( '1035-2341', '1', '1035-2347', '1', '1035-65', '1', '1035-
+46', '1');

foreach ( sort {$a cmp $b } keys %seq ) {
    print $_, "\n";
}
[download]

Comment on Sort hash keys Select or Download Code

Replies are listed 'Best First'.
Re: Sort hash keys by GrandFather (Saint) on Sep 17, 2010 at 10:04 UTC
On the face of it all you need is a small adjustment to your sort function: `my %seq = ('1035-2341', '1', '1035-2347', '1', '1035-65', '1', '1035-4 +6', '1'); foreach (sort {length $a <=> length $b \|\| $a cmp $b} keys %seq) { print $_, "\n"; }` [download] Prints: `1035-46 1035-65 1035-2341 1035-2347` [download] True laziness is hard work	[reply] [d/l] [select]
Re: Sort hash keys by johngg (Canon) on Sep 17, 2010 at 10:32 UTC
If, on the other hand, both numerical parts of your key are variant then you can split on the hyphen and do numerical sorts on each. `knoppix@Microknoppix:~$ perl -E ' > my %seq = map { $_ => 1 } qw{ > 1035-2341 > 1047-835 > 1035-2347 > 874-3971 > 1035-65 > 874-70 > 1035-46 > }; > say for > map { $_->[ 0 ] } > sort { $a->[ 1 ] <=> $b->[ 1 ] \|\| $a->[ 2 ] <=> $b->[ 2 ] } > map { [ $_, ( split m{-} ) ] } > keys %seq;' 874-70 874-3971 1035-46 1035-65 1035-2341 1035-2347 1047-835 knoppix@Microknoppix:~$` [download] I hope this is helpful. Cheers, JohnGG	[reply] [d/l]
Re^2: Sort hash keys by kalyanrajsista (Scribe) on Sep 17, 2010 at 11:00 UTC
Thanks JohnGG...It worked	[reply]
Re: Sort hash keys by JavaFan (Canon) on Sep 20, 2010 at 12:54 UTC
As expected a ST¹ solution was posted. As usual, no GRT² variant was. Since I think that if the list you're sorting is large enough to benefit from an ST, it'll benefit more from a GRT, here's the GRT variant: `my @seq = qw[ 1035-2341 1047-835 1035-2347 874-3971 1035-65 874-70 1035-46 ]; say for map {join "-", unpack "nn", $_} sort map {pack "nn", split "-"} @seq;` [download] Of course, for a 7 element list, neither ST nor GRT gains much benefits. ¹Schwartzian Transform ²Guttman Rosler Transform	[reply] [d/l]