Something like this:

use strict;
use warnings;

use Text::CSV;

my $csv = Text::CSV->new( { binary => 1 } );
my $tsv = Text::CSV->new( { binary => 1, sep_char => "\t" } );

open my $infh,  '<:utf8', 'input.csv'  or die $!;
open my $outfh, '>:utf8', 'output.tsv' or die $!;

while ( my $row = $csv->getline($infh) ) {
    $tsv->print( $outfh, $row );
    print $outfh "\n";
}
[download]

Small nitpicks, making it even easier:

• use the eol attribute to prevent the need for extra print calls
• "<:encoding(utf8)" is much safer than "<:utf8", esp on input
• use autodie to prevent all kinds of error checking (or add auto_diag => 1)

use strict;
use warnings;
use autodie;
use Text::CSV;

my $csv = Text::CSV->new ({ binary => 1 });
my $tsv = Text::CSV->new ({ binary => 1, sep_char => "\t", eol => "\n"
+ });

open my $infh,  "<:encoding(utf8)", "input.csv";
open my $outfh, ">:encoding(utf8)", "output.tsv";

while (my $row = $csv->getline ($infh)) {
    $tsv->print ($outfh, $row);
    }
[download]

otherwise a great reply!


Enjoy, Have FUN! H.Merijn

"perl -e ' $sep=","; while(<>) { s/\Q$sep\E/\t/g; print $_; } warn "Ch
+anged $sep to tab on $. lines\n" ' csvfile.csv > tabfile.tab"
[download]

#!/usr/bin/perl

use strict;
use warnings;

my $sep=","; 
open (my $csv_file , "<" , 'csvfile.csv');
open (my $tab_file , ">" , 'tabfile.tab');
while(<$csv_file>) { 
   s/\Q$sep\E/\t/g; 
   print $tab_file, $_;
 } 
warn "Changed $sep to tab on $. lines\n"
[download]

"Monster, The Cookie", "123 Sesame St, TV land"
[download]

You can open a new csv object with a different separator and just write it without having to contemplate cases like the above.

Thank you for the code Utilitarian! 'tabfile.tab' is created, but it's empty. I ran the script through debug and when I look at $_, I see the data in tab format. Why is 'tabfile.tab' empty though?

Because of a small error: one comma too many :)

while (<$csv_file>) { 
   s/\Q$sep\E/\t/g; 
   print $tab_file, $_;
   #              ^- That comma should not be there
   }
[download]

Other than that, I still think you ought to look into the proposed Text::CSV_XS or Text::CSV solutions.


Enjoy, Have FUN! H.Merijn

Notice that when you used perl -e ‘...whatever...’, you actually were executing a Perl script, consisting of that one string.

Most commonly, you build a command-file, written in Perl, that contains what you want to do.

There are two reasonable ways to do this.   One is to create a file with the extension .pl and execute it with:   perl whatever.pl.

Another way is, to make a command-file that can be run as an ordinary console command.   You’ll start the file with a “shebang” on the first line, e.g. #!/usr/bin/perl. On a Unix-like system, you use chmod to make the file “executable.”   Now, you can simply run the file, as you would any other command.   The shell will look at the “shebang” line and understand that it is meant for Perl.

(After so many years, Microsoft is beginning to offer a quasi-decent shell with their systems, which they have rather-amusingly dubbed PowerShell.™   My impression is that it vaguely similar in this regard...)

#!/usr/bin/perl -p
s/,/\t/g;
END{warn "Changed , to tab on $. lines\n"}
[download]

#!/usr/bin/perl -naF,
print join "\t",@F;
END{warn "Changed , to tab on $. lines\n"}
[download]

Here is short script that will print all the .csv formatted files in your current directory, then prompt you for the file to convert and the name to give the tab delimited file. Finally it will perform the conversion

#!/usr/bin/perl
# convert comma seperated file to tab delimited

use strict;
use warnings;

system ("clear");
system ("ls *.csv");
print "\n";
print 'What is the comma seperated file you need to convert? ';
chomp (my $csv_file = <> );
print 'What shall I name the new file? ';
chomp (my $tabd_file = <> );
system ("< $csv_file tr \",\" \"\t\" > $tabd_file");
exit;
[download]

This doesn't work correctly for commans contained in quotes:

1,abc,"def,ghi",jkl
[download]

Also, it doesn't work on MS Windows. Calling system for functionality already available in Perl itself isn't needed, anyway. There already are better answers.

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ