DreamT:

This ought to give you a head start. However, you didn't specify your problem very well, as I have no idea what type of treemenu you're wanting. (Web? Tk? Windows? ...?) So the code builds a hash containing the structure of your treemenu. Just add the appropriate code in dumptree to build your menu in whatever UI you need.

Roboticus@Roboticus-PC ~
$ cat treemenu.pl
use strict;
use warnings;

my %menu;
my $hr;
while (<DATA>) {
  chomp;
  my @keys = split /\|/,$_;
  next if @keys < 1;
  $hr = \%menu;
  while (my $k=shift @keys) {
    $$hr{$k} = {} unless exists $$hr{$k};
    $hr = $$hr{$k};
  }
}

dumptree('', \%menu);

sub dumptree {
  my $indent = shift;
  my $hr = shift;
  for my $k (sort keys %$hr) {
    print $indent, $k, "\n";
    if (keys %{$$hr{$k}}) {
      dumptree($indent."  ", $$hr{$k});
    }
  }
}

__DATA__
CDs
Books|Adventure
Movies|Music
Books
Books|Sports
Movies
Movies|Adventure
Books|Drama
CDs|Classic


Roboticus@Roboticus-PC ~
$ perl treemenu.pl
Books
  Adventure
  Drama
  Sports
CDs
  Classic
Movies
  Adventure
  Music

Roboticus@Roboticus-PC ~
$
[download]

...roboticus

Hi,
I'm supposed to build a nested ul/li list. I think that this will do the trick:) Thank you!

Split each line on the divider (eg, split /\|/, ...) to get one or more fields. If there's one field, make sure a key with that value exists in some hash. If there's one field, push the second field's value onto the value (an array reference) associated with the first field (all this in the same hash mentioned before). If there are more levels, decide whether you want the third, etc fields to be sibling to the second value or children of it.

For example, for sibling-only behavior:

my %menu_structure;
for (@menu_specification) {
  my ($toplevel, @sublevel) = split /\|/;
  unless (@fields) {
    $menu_structure{$toplevel} = [];
  }
  else {
    push @{ $menu_structure{$toplevel} }, @sublevel;
  }
}
[download]