@array =
   sort {
      my ($digits_from_a) = $a =~ /(\d+)\z/;
      my ($digits_from_b) = $b =~ /(\d+)\z/;
      $digits_from_b <=> $digits_from_a
   }
   @array;
[download]

Same, but a bit more terse:

@a = sort { ($b =~ /(\d+)\z/)[0] <=> ($a =~ /(\d+)\z/)[0] } @a;
[download]

The aforementioned Schwartzian Transform is an attempt to optimise this.

use strict;

my @array = qw(abc1 abc32 abc64 abc8 abc16);

my @sorted_array = map { $_->{string} }
                    sort { $b->{number} <=> $a->{number} }
                      map { /(\d+$)/; { string => $_, number => $1 } }
                        @array;
[download]

If the array to be sorted is very large, a Guttman Rosler Transform (GRT) may be advantageous (see A Fresh Look at Efficient Perl Sorting and Understanding transformation sorts (ST, GRT), the details):

>perl -wMstrict -le
"my @ra = qw(abc1 abc32 abc64 abc8 abc16);
 ;;
 my $wide = 15;
 my @sorted =
   map unpack(qq{x$wide a*}),
   reverse sort
   map sprintf('%0*d%s', $wide, m{ (\d+) \z }xms, $_),
   @ra
   ;
 ;;
 print qq{@sorted};
"
abc64 abc32 abc16 abc8 abc1
[download]

See also Sort::Maker.