Note that this common precedence booboo can be avoided by following the advice in Chapter 4, "Values and Expressions" of Perl Best Practices.

See especially item 4.16: "Don't mix high- and low-precedence booleans".

++$any{$_}
   for
      keys(%hash1),
      keys(%hash2),
      keys(%hash3),
      keys(%hash4);

for (keys(%test_hash)) {
   print("$test_hash{$_}\n")
      if !$any{$_};
}
[download]

My preference is for code to read exactly like the English that describes it. Your spec says "not ... any", so the closest I can come to that is:

use List::MoreUtils qw(any);

foreach my $k (keys %test_hash)
{
  if (not any { exists $_->{$k} } \%hash1, \%hash2, \%hash3, \%hash4)
  {
    print $k;
  }
}
[download]

use List::MoreUtils qw(none);

foreach my $k (keys %test_hash)
{
  if (none { exists $_->{$k} } \%hash1, \%hash2, \%hash3, \%hash4)
  {
    print $k;
  }
}
[download]

I don't actually suggest this over Anonymous Monk's solution for speed reasons. I suggest this because the code reads linguistically the same as your spec. It just happens that it performs as well or better than the grep solution.

The grep solution actually returns a list in boolean context. My solution returns boolean in boolean context. In my mind, that is a win right there because the code says the same thing as the spec. There are fewer mental logic changes where someone may have to stop and think about how it works. Reading just like the spec means that the maintenance programmer will just be able to read the code without even necessarily being familiar with List::MoreUtils. In fact, the only reason they would check the docs for List::MoreUtils would be to see what other cool things it had.

(You could also use (core module) List::Util's first in the exact same way, but it's not going to make a noticeable difference unless you've benchmarked that this is slowing you down.)

You get the key from %test_hash, and check if it exists as a key in the other hashes, but if it doesn't, you print out %test_hash value associated with the key. Maybe yoou were just trying to simplify your code for us, but it does suggest you're confusing keys and values.

Besides the mixed-precedence bolean operations, I mean ... I've been finding perlcritic useful in isolating tons of minor weaknesses in some ghastly code I'm bringing up to modern standards, I'll probably be using it more often in my routine development. Mixed-precedence booleans is just one of many things it warns about ... Be sure you have it on the harshest setting.