in reply to Re: beginner - ordering tuples
in thread beginner - ordering tuples

Thanks for your reply. I've actually used the solution given above my rolf and it works great. However I have now found an additional need for the ordering: If some tuples have the same number on the first position I need them to be ordered so that the HIGHEST number in the second position comes first 
e.g.

<12, 34>
<12, 43>
<12,10> becomes

<12,43>
<12,34>
<12,10>

[download]
I couldn't modify the code to get it to do what I wanted

Replies are listed 'Best First'.
Re^3: beginner - ordering tuples
by LanX (Saint) on Nov 13, 2010 at 14:03 UTC
    do you mind if I simplify it to a one liner?

    use strict;
use warnings;
 
my @datas;
 
# for (<DATA>){
#   push @datas, [ m/<(\d+),(\d+)>/ ];
# }
 
@datas = sort { $a->[0] <=> $b->[0] || $a->[1] <=> $b->[1] } 
              map { [ m/<(\d+),(\d+)>/ ] } <DATA>;
 
use Data::Dumper;
print Dumper \@datas;
 
__DATA__
<7,22>
<12,20>
<7,15>
<1,5>
<7,10>

    [download]

    please see sort about how the boolean three states condition decides about the ordering.

    the perlop || is - like in C - short circuiting, that is the RHS is only evaluated (and returned) when the LHS is false (i.e 0 if <=> compares equal values).

    If your tuples have more than 2 elements you should ask for a generic solution.

    Cheers Rolf

[reply]
[d/l]
[select]

      In your elegant solution, you need to switch around your second conditional to:

      $b->[1] <=> $a[1]
[reply]
[d/l]
        Right, I missed that the second position should be descending.

        You forgot a dereferencing: $b->[1] <=> $a->[1]

        Cheers Rolf

[reply]
[d/l]
Re^3: beginner - ordering tuples
by Anonymous Monk on Nov 13, 2010 at 13:33 UTC
    I modified the above as follows but it will probably make you perl programmers cringe with despair. Sorry rolf for desecrating your original answer :) 
    

use strict;
use warnings;
 
 $" = ', ';
my @datas;
 
#- parse input
for (<DATA>){
  my @entries = m/<(\d+),(\d+)>/;
  push @datas, [@entries];
  
 
}
 
#- sort
@datas=sort sort_test @datas;

#- output
use Data::Dumper;
print Dumper \@datas;
 
sub sort_test()
{
    if ($a->[0] < $b->[0])
    {
        return -1;
    }elsif ($a->[0] > $b->[0]){
        return 1
    }else {
        if ($a->[1] > $b->[1]) {
            return -1;
        } elsif ($a->[1] < $b->[1]) {
            return 1;
        } else {
            return 0;
        }
    }
    
}
__DATA__
<12,20>          
<1,5>
<7,10>
<7,12>
<7,15>

    [download]
[reply]
[d/l]
      I've just noticed, why has it put some of the output in single quotes: (look at the first and last one). I did it with different data and the last 2 tuples had quotes around the second value. 
      $VAR1 = [
          [
            1,
            '5'
          ],
          [
            7,
            15
          ],
          [
            7,
            12
          ],
          [
            7,
            10
          ],
          [
            12,
            '20'
          ]
        ];

      [download]
[reply]
[d/l]
        why has it put some of the output in single quotes:

        The input array is initialised with strings. Left unmodified, all the values would be output in quotes.

        During the sort process, any values that are compared as numbers using <=>, will first be converted, internally, to their (binary) numeric representation.

        But as the first & last pairs in your example have unique first elements (1 & 12), there is never any need to compare their second elements, hence they are never converted to numeric representation, and so are output as strings.

        Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
        "Science is about questioning the status quo. Questioning authority".
        In the absence of evidence, opinion is indistinguishable from prejudice.
        +
[reply]
[d/l]

In Section Seekers of Perl Wisdom