open(INP, '<:utf8',$ARGV[0]) or die...
[download]

decode works, except it takes a scalar

my @encoded_hira = <INP>;
my @decoded_hira = map { decode('UTF-8', $_) } @encoded_hira;
my @decoded_romaji = kana2romaji(@decoded_hira);
my @encoded_romaji = map { encode('UTF-8', $_) } @decoded_romaji;
print OUTP @encoded_romaji;
[download]

binmode works, except it takes a file handle.

binmode INP, ':encoding(UTF-8)';
binmode OUTP, ':encoding(UTF-8)';
[download]

But the simplest way is to pass that directive to open.

open(INP,  '<:encoding(UTF-8)', $ARGV[0])
open(OUTP, '>:encoding(UTF-8)', $ARGV[1])
[download]

use utf8; tells Perl the Perl source is UTF-8. Not relevant here.

_utf8_on is an unsafe version of decode. Like decode, it would have worked if you had used it properly.

(Note that the module is wrong to check for the UTF8 flag. Informally, this is called "The Unicode Bug". It's trying to detect if you made an error, but it can incorrectly flag valid inputs as errors.)

Because you admitted unabashedly you're new to Perl, and because you pleaded very graciously for our help, I've taken the liberty of refactoring your script a tiny bit. I've incorporated idioms of Modern Perl and a few Perl best practices gleaned from Perl Best Practices.

#!perl
#
# hiragana2romaji.pl - Convert hiragana text to romaji text

use strict;
use warnings;
use autodie;

use Lingua::JA::Moji qw( kana2romaji );

@ARGV == 2
    or die "Usage: perl $0 <hiragana file> <romaji file>\n";

my $hiragana_file = shift @ARGV;
my $romaji_file   = shift @ARGV;

open my $hiragana_fh, '<:encoding(UTF-8)', $hiragana_file;
open my $romaji_fh,   '>:encoding(UTF-8)', $romaji_file;

while (my $hiragana_text = <$hiragana_fh>) {
    chomp $hiragana_text;
    my $romaji_text = kana2romaji($hiragana_text);
    print {$romaji_fh} "$romaji_text\n";
}

close $hiragana_fh;
close $romaji_fh;

exit 0;
[download]

I tested the Perl script on hiragana text in Unicode Normalization Form D as well as in Normalization Form C. It doesn't handle NFD properly.

For this input…

NFC どらいどまんごす
NFD どらいどまんごす

…it generates this output…

NFC doraidomangosu
NFD to゙raito゙manko゙su

…which isn't right. The module Lingua::JA::Moji isn't accounting for the possibility of Japanese kana in their decomposed form (NFD).

This may not matter to you for your application, but I felt it was worth pointing out to you in any case. If it does matter to you, then you might suggest to the author of Lingua::JA::Moji that he use the core module Unicode::Normalize to normalize the characters to NFC prior to converting them from kana to romaji.

Normalization Form C (NFC)

U+3069 HIRAGANA LETTER DO
U+3089 HIRAGANA LETTER RA
U+3044 HIRAGANA LETTER I
U+3069 HIRAGANA LETTER DO
U+307E HIRAGANA LETTER MA
U+3093 HIRAGANA LETTER N
U+3054 HIRAGANA LETTER GO
U+3059 HIRAGANA LETTER SU
[download]

Normalization Form D (NFD)

U+3068 HIRAGANA LETTER TO
U+3099 COMBINING KATAKANA-HIRAGANA VOICED SOUND MARK
U+3089 HIRAGANA LETTER RA
U+3044 HIRAGANA LETTER I
U+3068 HIRAGANA LETTER TO
U+3099 COMBINING KATAKANA-HIRAGANA VOICED SOUND MARK
U+307E HIRAGANA LETTER MA
U+3093 HIRAGANA LETTER N
U+3053 HIRAGANA LETTER KO
U+3099 COMBINING KATAKANA-HIRAGANA VOICED SOUND MARK
U+3059 HIRAGANA LETTER SU
[download]