As jwkrahn had pointed out, the string is not clobbered by his code. You need to supply the d flag to actually delete the characters.

knoppix@Microknoppix:~$ perl -E '
> $str = q{3 * (4 + 5) / (6 - 7)};
> say $str;
> $lb = $str =~ tr/(//;
> $rb = $str =~ tr/)//;
> say qq{left : $lb};
> say qq{right: $rb};
> say $str;
> $dig = $str =~ tr/0-9//d;
> say qq{digit: $dig};
> say $str;'
3 * (4 + 5) / (6 - 7)
left : 2
right: 2
3 * (4 + 5) / (6 - 7)
digit: 5
 * ( + ) / ( - )
knoppix@Microknoppix:~$
[download]

I hope this is helpful.

If you don't want to clobber the $testString contents

Both:

    my $l_count = $testString =~ tr/(//;
    my $r_count = $testString =~ tr/)//;
[download]

and:

    my $l_count = ($testString =~ tr/(/(/);
    my $r_count = ($testString =~ tr/)/)/);
[download]

do exactly the same thing.    Neither of which "clobbers" the string.

not sure if that is returning in a list context

The left-hand side of the assignment determines context, in this case scalar, so the parentheses are irrelevant.

If you want to find out whether parenthesis are balanced in a string, you do not need a complicated regexp. In fact, you could even do it without a regexp at all, but let me present you a solution with a simple regexp:

sub is_balanced {
    my $_ = shift;
    my $c = 0;

    while (/([()])/g) {
        if ($1 eq '(') {$c++; next}
        return if --$c < 0;
    }

    $c == 0;
}
[download]

The trick is to keep a counter. Increase the counter by 1 each time you see a '(', decrement the counter by 1 each time you see a ')'. If the counter ever becomes less than 0, or if the counter isn't 0 when reaching the end of the string, the parens aren't balanced. Otherwise, they are.