Try the following:

$hash->{$name} = {
  TYPE => 9001,
  VALUE => "UNINITIALIZED",
}
[download]

BTW, this is just a hash of hashes, not necessary to be an object, so perlboot is not necessarily the best reference. Try looking for HoH in the monastery.

use warnings;
use strict;

package Cow;
{   
    sub speak {
        print "Moo\n"
    }
}

package Horse;
{   
    sub speak {
        print "Hi, my name is Ed\n"
    }
}

package Sheep;
{   
    sub speak {
        print "Baaaah\n"
    }
}

my @pasture = qw(Cow Cow Horse Sheep Sheep);

foreach my $animal (@pasture) {
    $animal = (bless \do{my $anon}, $animal);
    $animal->speak();
}
[download]

Moo
Moo
Hi, my name is Ed
Baaaah
Baaaah
[download]

1) What does do{my $anon} accomplish?

2) What does your code accomplish that this doesn't:

my @pasture = qw(Cow Cow Horse Sheep Sheep);

for my $beast (@pasture) {
    $beast->speak();
}
[download]

The \do{my $anon} creates an anonymous reference which can be blessed. To be honest it doesn't do anything more than your simpler example in this case.

Update: To clarify. Just using the plain text string is a class call - the first argument passed to each subroutine will be the name of the class (Cow, Horse, Sheep). My version, which creates a reference to an anonymous scalar, is an object call - the first argument passed to each argument is a unique reference referring to each animal, rather than each species. So this enables other magic to be performed because we can identify not just the type of animal (the class) the which Cow or Sheep, if we need to. It is also the basis of inside-out objects. I'm not clear if the questioner needs this extra level of control though.

I'm not entirely clear on what you want to accomplish, but maybe what you meant was that you want the token type of each token to trigger certain processing? For example, if you have a name "foo" and your parser says it is a variable declaration token, you want to be able to trigger certain processing rules depending on whether that declaration is for an integer, email address, day of week, or some other special type?

If you need to trigger special processing based solely on the combination of a name and a type, you could use a slightly modified version of cdarke 's solution:

use strict;
use warnings;

package Cow;
{
  sub speak { print ${$_[0]}, " says Moo\n" }
}

package Horse;
{
    sub speak { print ${$_[0]}, " says 'Hi, my name is Ed'\n" }
}

package Sheep;
{
    sub speak { print ${$_[0]}, " says Baaaah\n"  }
}

# mapping names to types
my %Pasture = ( Bessie => 'Cow',
                , Annie => 'Cow',
                , Joe => 'Horse'
                , Lily => 'Sheep'
                , James => 'Sheep'
               );

while (my ($name, $animal) = each(%Pasture)) {
  # assign a class to each name based on type
  my $oAnimal = bless(\do{my $anon=$name;}, $animal);

  # do processing that involves both name and type
  $oAnimal->speak();
}
[download]

Thanks for the post!

Just so you know, this code:

&{$animal."::speak"};
[download]

doesn't create anything. It uses what's called a "symbolic reference" to look up a subroutine that already exists. A symbolic reference is just a string, and when you try to dereference a string, {}, perl looks up the string in the symbol table, and in this case retrieves the subroutine, &, with that name.

You can use typeglobs to create new entries in the symbol table, for instance:

*Cow::speak = sub {print "mooo\n"};

Cow->speak();

--output:--
mooo
[download]

The rest of your post doesn't make any sense to me.