If there was just one DATASOURCE tag with a specific name you could use code like this:

use strict;
use warnings; no warnings 'uninitialized';

use XML::Rules;

my $parser = XML::Rules->new(
    stripspaces => 7,
    rules => {
        _default => 'content',
        DATASOURCE => 'by NAME',
        NAGIOS => 'pass no content',
    },
);

my $data = $parser->parse($file);

#use Data::Dumper;
#print Dumper($data);

print $data->{cur}{ACT};
[download]

If there are more it's a bit more complicated as there is no builtin rule you could use and it's harder to get at the values you want:

my $parser = XML::Rules->new(
    stripspaces => 7,
    rules => {
        _default => 'content',
        DATASOURCE => sub {
            my ($tag,$attrs) = @_;
            return '@'.$attrs->{NAME} => $attrs;
        },
        NAGIOS => 'pass no content',
    },
);

my $data = $parser->parse($file);

#use Data::Dumper;
#print Dumper($data);

foreach my $datasource (@{$data->{cur}}) {
    print $datasource->{ACT}, "\n";
}
[download]

Of course if you do know you will not need the other data in the file you can ignore it and simplify the datastructure:

my $parser = XML::Rules->new(
    stripspaces => 7,
    rules => {
        _default => '',
        'NAME,ACT' => 'content',
        DATASOURCE => sub {
            my ($tag,$attrs) = @_;
            return '@'.$attrs->{NAME} => $attrs->{ACT};
        },
        NAGIOS => 'pass no content',
    },
);

my $data = $parser->parse($file);

#use Data::Dumper;
#print Dumper($data);

print join( ", ", @{$data->{cur}}), "\n";
[download]