Or, if it's always a US-based school web address, then checking that it ends in .edu (or I guess .net, .com, or .org, and maybe .us) might be enough.

As for readability and best practices, I'd write that snippet as follows, tested with the provided data:

#! /usr/bin/perl;
use strict;
use warnings;
use autodie; # errors from open made fatal

sub DEBUG { 1 }

my $filelist = 'tmp.txt';
open my $filelist_handle, '<', $filelist;
while (<$filelist_handle>) {
    chomp;
    my ($type, $school) = m!
      ^                 # anchor to beginning
      /home/test/       # common to all lines
      (\w{3})           # capture 'type'
      /\.date_[^.]+     # common to all lines
      (?:               # non-capturing group
        .+?(\w+)\.\w+$  # capture domain name?
        |               # or don't capture
      )                 # end group
    !x # /x flag means ignore white space in pattern
    or next; # skip line if it doesn't match
    
    # do extra check that $school is acceptable
    $school //= 'null'; # regex gives undef if not found
    
    if (DEBUG) {
        print "match: $_\n";
        print "\ttype: $type\n";
        print "\tschool: $school\n";
    } else {
        open my $line_handle, '<', $_;
        while (<$line_handle>) {
            print "Type:$type:School:$school:File:$_\n";
        }
    }
}
[download]

Example debug output:

match: /home/test/abc/.date_run_dir
        type: abc
        school: null
match: /home/test/def/.date_run_dir
        type: def
        school: null
match: /home/test/abc/.date_file_sent.email@wolverine.cole.edu
        type: abc
        school: cole
match: /home/test/abc/.date_file_sent.dp3.drew.net
        type: abc
        school: drew
match: /home/test/def/.date_file_sent.email@wolverine.cole.edu
        type: def
        school: cole
match: /home/test/def/.date_file_sent.dp3.drew.net
        type: def
        school: drew
[download]

Thank you. This is great. Thanks a lot for breaking down that cryptic regex as well. I did try and test this, but had some issues with:

    # do extra check that $school is acceptable
    $school //= 'null'; # regex gives undef if not found
[download]

Error msg:

Search pattern not terminated

I commented that out and it run, although it had these errors:

match: /home/test/abc/.date_run_dir
    type: abc
Use of uninitialized value in concatenation (.) or string at ./test7.p
+l line 31, <$_[...]> line 1.
    school: 
match: /home/test/def/.date_run_dir
    type: def
Use of uninitialized value in concatenation (.) or string at ./test7.p
+l line 31, <$_[...]> line 2.
    school:
[download]

Also would you pls show me to extract values from the files I match? Can I do this in the same pass that I peform the regex? Example values from file (.date_run_dir, etc)

$ cat .date_run_dir .date_file_sent.*
/project/school/data/feed_abc_2010120816.ext3
mail_abc.dat.2010120816.ext3
mail_abc.dat.2010120816.ext3
[download]

Oh, sorry about that error. //= is only in Perl 5.10.0 and later, and I should have noted that. The statement is equivalent to $school = 'null' unless defined $school;

For the values inside the listed files, you could use a similar regex (or build it and the original from another which contains the common parts of both) inside that inner while loop, yes?

#!/usr/bin/perl -w
use strict;

while (<DATA>)
{
   chomp;
   my ($basedir, @dot_names) = split(/\./,$_);
   my $type = (split('/',$basedir))[-1];

   my $school = "null";  
   $school=$dot_names[-2] if (@dot_names >1);
  
   #open the file here and use the variables as prefix for each line
   print "type: $type  school: $school\n";  
}
=prints 
type: abc  school: null
type: def  school: null
type: abc  school: cole
type: abc  school: drew
type: def  school: cole
type: def  school: drew
=cut

__DATA__
/home/test/abc/.date_run_dir
/home/test/def/.date_run_dir
/home/test/abc/.date_file_sent.email@wolverine.cole.edu
/home/test/abc/.date_file_sent.dp3.drew.net
/home/test/def/.date_file_sent.email@wolverine.cole.edu
/home/test/def/.date_file_sent.dp3.drew.net
[download]

@Marshall. Thanks! I can see how split can come in very handy as well. You made it look easy.