in reply to Re^2: Tk and Threads
in thread Tk and Threads

With a minor change to the code I posted, the button can be used to pause & resume the threads:

#!perl -slw
use strict;
use Time::HiRes qw [ sleep ];
use threads;
use Thread::Queue;

use constant { IDLE => 0, WORK => 1 };

sub work{
    my( $id, $delay, $Q ) = @_;
    my $n = 0;
    my $state = WORK;

    local $SIG{QUIT} = sub{ $state ^= 1 };

    while( sleep( $delay ) && ++$n <= 100 ) {
        sleep 1 while $state == IDLE;
        $Q->enqueue( "$id:$n" );
    }
}

my $Q = new Thread::Queue;

my @threads = map threads->new( \&work, $_, 0.1 * $_, $Q ), 1 .. 2;

require Tk::ProgressBar;

my $mw = MainWindow->new;

my $pb1 = $mw->ProgressBar()->pack();
my $bt1 = $mw->Button(
    -text => 'Pause/resume thread 1',
    -command => sub { $threads[0]->kill('QUIT') }
)->pack;

my $pb2 = $mw->ProgressBar()->pack();
my $bt2 = $mw->Button(
    -text => 'Pause/resume thread 2',
    -command => sub {  $threads[1]->kill('QUIT') }
)->pack;

my $repeat;
$repeat = $mw->repeat( 100 => sub {
    while( $Q->pending ) {
        my( $id, $progress ) = split ':', $Q->dequeue;
        return unless $progress;
        ( $id == 1 ? $pb1 : $pb2 )->value( $progress );
        if( $id == 2 && $progress == 100 ) {
            $repeat->cancel;
            $mw->exit;
        }
    }
} );


$mw->MainLoop;

END{ $_->join for @threads; }

[download]

But that is actually easier to achieve using a simple shared variable.

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
"Science is about questioning the status quo. Questioning authority".
In the absence of evidence, opinion is indistinguishable from prejudice.

Replies are listed 'Best First'.
Re^4: Tk and Threads
by Dirk80 (Pilgrim) on Dec 22, 2010 at 10:56 UTC

    Pausing and resuming is great. But what I need is a restart.

[reply]
      But what I need is a restart.

      What do you mean by "a restart"?

      Do you mean abandon the thread regardless of what it is doing and start a new one?

      Or, undo everything the thread has done to this point and have it start over?

      In short. What are you trying to achieve?

      And please don't start repeating your talk about IDLE & WORK states, because without definition in concrete terms of what actual happens when a transition from one state to the other occurs, they are nothing more than meaningless words!

      Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
      "Science is about questioning the status quo. Questioning authority".
      In the absence of evidence, opinion is indistinguishable from prejudice.
[reply]

        With a restart I mean undoing everything the thread has done and then starting it again.

        I have a TK Gui. The user is pressing the start button. Then a long action is started (in a thread). There is also a cancel button. If the user is pressing the cancel button then the long action shall be stopped immediately. Everything what has been done until now shall be undone (e.g. deleting a file which was created by this thread). When the user then again is pressing the start button the long action shall be started again. Because there are a lot of other GUI-Elements which contain information for the thread a new pressing of the start button has to give this information to thread.

[reply]

In Section Seekers of Perl Wisdom