my @words = split ' ', $line;
my @boy_idxs = grep $words[$_] eq 'boy', 0..$#words;
$words[$boy_idxs[rand(@boy_idxs)]] = 'man';
$line = join ' ', @words;
[download]

Update: This one doesn't mess up the whitespace:

my @boy_idxs;
push @boy_idxs, $-[0] while $line =~ /\b boy \b/xg;
substr($line, $boy_idxs[rand(@boy_idxs)], length('boy')) = 'man';
[download]

@-

#!/usr/bin/perl -w
use strict;

my $line='boy boy girl boy girl boy girl girl';

my $count =()= $line =~ /boy/g;      #number of boys on line
print "number of boys = $count\n";

my $num = int(rand($count)) + 1;     #1..$count
print "looking for nth boy: $num\n";

my $found_position =-1;
while ($num--)
{
   $found_position= index($line,"boy", $found_position+1);
   print "replace index = $found_position\n";
}

substr ($line, $found_position, length("boy"), "cowboy");

print "$line\n";

__END__
One example run:
number of boys = 4
looking for nth boy: 3
replace index = 0
replace index = 4
replace index = 13
boy boy girl cowboy girl boy girl girl
[download]

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my $line='boy boy girl boy girl boy girlyboy girl girl';
my @indicies;

while ($line =~ /\bboy\b/gi)
{
   push (@indicies, pos($line)-3); #pos is a bit tricky
}

print Dumper \@indicies;

my $num = int(rand(@indicies));     #0..$count
print "line = $line\n";
print "looking for nth boy: ",$num+1,"\n";

substr ($line, $indicies[$num], length("boy"), "cowboy");

print "       $line\n";

__END__
Some runs:
$VAR1 = [
          0,
          4,
          13,
          22
        ];
line = boy boy girl boy girl boy girlyboy girl girl
looking for nth boy: 3
       boy boy girl cowboy girl boy girlyboy girl girl
.....
$VAR1 = [
          0,
          4,
          13,
          22
        ];
line = boy boy girl boy girl boy girlyboy girl girl
looking for nth boy: 1
       cowboy boy girl boy girl boy girlyboy girl girl
.....
$VAR1 = [
          0,
          4,
          13,
          22
        ];
line = boy boy girl boy girl boy girlyboy girl girl
looking for nth boy: 4
       boy boy girl boy girl cowboy girlyboy girl girl
[download]

Here's an alternative way that uses three idioms from the Perl FAQ.

How can I count the number of occurrences of a substring within a string?
How do I get a random number between X and Y?
How do I change the Nth occurrence of something?

#!perl

use strict;
use warnings;
use feature qw( say );
use English;

my $line = 'boy boy girl boy girl    boy girl girl';

say $line;

my $match_pattern      = qr/\bboy\b/;
my $replacement_string = 'man';

my $total_matches = () = $line =~ m/$match_pattern/g;

# Generate a random number from 1 to $total_matches...
my $random_number = int(rand($total_matches)) + 1;
my $match_number  = 1;

$line =~ s{
    $match_pattern
}{
    $match_number++ == $random_number ? $replacement_string : $MATCH;
}gex;

say $line;

exit 0;
[download]

Just curious, what if instead of replacing ONE boy, we are going to replace N boys? substr will definitely fail if the replacement string is of a different length?

You replied to my post, but I think you intended to ask someone else this question — someone who used substr in his or her solution.

My solution works with any arbitrary regular expression pattern and any arbitrary replacement string. I think my solution is the one most likely to earn the OP an A+.

Yet another solution (without claiming efficiency over previous solutions)

#!/usr/bin/perl -wl
use strict;
my $str = "boy boy girl boy girl boy girl girl";
my $l = int(rand(rindex($str,"boy") - 1));
$str =~ s/^(.{$l}.*?)\bboy\b/$1man/;
print $str;
[download]

Unfortunately, this one isn't very random - at least with regard to the first occurrence of 'boy'. I see where you tried to correct it with the '- 1', but that doesn't work:

#!/usr/bin/perl -wl
use strict;

my %data;
for (1..10000){
    my $str = "boy boy girl boy girl boy girl girl";
    my $l = int(rand(rindex($str,"boy") - 1));
    $str =~ s/^(.{$l}.*?)\bboy\b/$1man/;
    $data{$str}++;
}

print "$_: $data{$_}" for sort keys %data;
[download]

Output:

boy boy girl boy girl man girl girl: 3323
boy boy girl man girl boy girl girl: 4310
boy man girl boy girl boy girl girl: 1881
man boy girl boy girl boy girl girl: 486
[download]

(Don't ask me why I know about this problem. :)))


--
"Language shapes the way we think, and determines what we can think about."
-- B. L. Whorf

my $N = 1;  # Number of replacements.
my $a = "boy boy girl boy girl boy girl girl";
my @b = split ' ', $a;
my $c = grep {$_ eq "boy"} @b;
my @d = map {$_ eq "boy" && rand($c--) < $N ? do {$N--; "man"} : $_} @
+b; 
say "@d";
[download]

Somewhat different approach:

#!/usr/bin/perl -w
use strict;

my $line='boy boy girl boy girl boy girl girl';
my ($pos, @pos);
my $last = 0;
{
    $pos = index $line, 'boy', $last;
    last if $pos == -1;
    push @pos, $pos;
    $last = $pos + 1;
    redo;
}
substr $line, $pos[rand(@pos)], 3, 'man';
print "$line\n";
[download]

Update: Same idea but using 'pos()':

#!/usr/bin/perl -wl
use strict;

my @pos;
$_ = 'boy boy girl boy girl boy girl girl';
push @pos, pos() - 3 while /boy/g;
substr $_, $pos[rand @pos], 3, 'man';
print;
[download]