Let me see if I have this straight.

• Your input is divided into blocks.
• Each block starts with a weird line saying ENERGY.
• Within each block you have lines with a vertex, G, then vertices that the first vertex is connected to.
• You don't want to count a vertex as being connected to 0 or itself. (In your data this solves your last column issue, and I think is the real requirement.)
• Every block has the same vertices. (This is a big assumption that is implicit in how you want to process everything.)
• First you want to go through the first block, then print off all of the vertices.
• Then for each block, at the end of the block,'
  • For each vertex
    • For each vertex it is connected to
      • print off first vertex, second vertex, and the total multiplicity you have found.
  Note in particular that in my understanding if a pair of vertices does not appear in a later block, it won't be printed in *edges.

If this is what you are asking for, the following code should do it:

#!/usr/bin/perl -w
use strict;

# This should really be passed in on the command line or something.
my $data_file = "HIVgag.ct";

# Find the vertices.
my @vertices;

open(my $fh, "<", $data_file) or die "Can't open '$data_file': $!";
while (<$fh>) {
    if (/energy/i) {
        if (not @vertices) {
            # This is the first line of the first block.  Do nothing.
            next;
        }
        else {
            # We have completed the first block.
            last;
        }
    }

    my @row = split /\s+/, $_;
    push @vertices, $row[0];
}

# Scalar context turns @vertices into the number of elements it has.
print "*vertices " . @vertices . "\n";
for my $vertex (@vertices) {
    print "$vertex G\n";
}
print "*edges\n";

seek($fh, 0, 0);

my %connect;
my $position = @vertices - 1;
while (<$fh>) {
    $position++;
    if (/energy/i) {
        if ($position != @vertices) {
            die "In line $., too few vertices found";
        }
        $position = -1;
        next;
    }

    my ($this_vertex, $type, @row) = split /\s+/, $_;
    if ($this_vertex ne $vertices[$position]) {
        die "Unexpected vertex '$this_vertex' at line $.";
    }

    for my $other_vertex (@row) {
        if (0 == $other_vertex or $this_vertex == $other_vertex) {
            next;
        }
        my $key = "$this_vertex $other_vertex";
        $connect{$key}++;
        print "$key $connect{$key}\n";
    }
}
[download]

Things to note.

• I've used warnings and strict.pm. This is a very good habit that will catch a lot of bugs. Absolutely do this.
• My error message on the open uses $! as perlstyle recommends.
• Note all of the sanity checking to verify that the file looks exactly like I think it should.
• I am extremely puzzled at why you want to print the same pair of vertices multiple times in your *edges section. This makes no sense to me. Instead I would recommend taking out the print from my inner loop, and then add a short section at the end that prints out the contents of multiplicity. Like this:

  for my $vertex_pair (sort keys %multiplicity) {
      print "$vertex_pair $multiplicity{$vertex_pair}\n";
  }
  [download]

• I have no idea what the purpose of G is in your file. I suspect from your code that it has to do with DNA, and I wonder whether you should be dropping it from the edges section.