A technique I often use for this sort of problem is to have the regex work its way over the problematic section one character at a time and use look around assertions to handle the quoting. Consider:

use warnings;
use strict;

my $line = qq{Test #1 'Show me Waynes world','Jennys Basketball shoes'
+\n};
print "< $line";
$line =~ s/(['"]).+?(['"])/$1SSS$2/g;
print "> $line";

$line = qq{Test #2 'Show me Wayne\\'s world','Jenny\\'s Basketball sho
+es'\n};
print "< $line";
$line =~ s/(['"]) (?: (?! (?<!\\)\1 ) .)+ \1/$1SSS$1/gx;
print "> $line";
[download]

Prints:

< Test #1 'Show me Waynes world','Jennys Basketball shoes'
> Test #1 'SSS','SSS'
< Test #2 'Show me Wayne\'s world','Jenny\'s Basketball shoes'
> Test #2 'SSS','SSS'
[download]

Note that I removed to redundant sprintfs, showed before and after versions of the test strings, and fixed the quote issue in the second test string.

As a matter of technique, you should print the value of $line before you change it to make sure it is what you think it is. In your second test, you need to escape the \ after Wayne. The following code should get you started:

$line = sprintf qq{Test #1 'Show me Waynes world','Jennys Basketball s
+hoes'\n};
print $line;   # <- added this line
$line =~ s/(')[^'\\]*(?:\\.[^'\\]*)*(')/$1SSS$2/g;
print $line;

$line = sprintf qq{Test #2 'Show me Wayne\\'s world','Jenny\\'s Basket
+ball shoes'\n};  # <- changed this line (two extra \ added)
print $line;   # <- added this line
$line =~ s/(')[^'\\]*(?:\\.[^'\\]*)*(')/$1SSS$2/g;
print $line;
[download]

Update: Matching quoted strings is also discussed in perlre (in the "Quantifiers" section), where they suggest /"(?:[^"\\]++|\\.)*+"/ (perl 5.10 and above); see the discussion in perlre for more details. See also this stack overflow question and $RE{quoted} in Regexp::Common.

use strict; 
use warnings; 

my $line = qq{Test #1 'Show me Waynes world','Jennys Basketball shoes'
+\n};
$line =~ s/(?<!\\)(['"]).+?(?<!\\)(['"])/$1SSS$2/g;
print $line;

$line = q{Test #2 'Show me Wayne\'s world','Jenny\'s Basketball shoes'
+} . "\n";
$line =~ s/(?<!\\)(['"]).+?(?<!\\)(['"])/$1SSS$2/g;
print $line;

__END__

Test #1 'SSS','SSS'
Test #2 'SSS','SSS'
[download]

Update: YAPE::Regex::Explain to the rescue:

Take a look at perlre - Regular Expressions, Subsection Quantifiers, Second to last paragraph.

The most efficient way to capture a single or double quoted string is to use an independent subexpression to avoid backtracking. The below example will also avoid the case where the backslash is escaped itself.

use strict;

my $single_quote_re = qr{
    '
    (?:
        (?> [^\\']+ )
    |
        \\ .
    )*
    '
}sx;

# Normal String
my $line = qq{Test #1 'Show me Waynes world','Jennys Basketball shoes'
+\n};
print $line;
$line =~ s/$single_quote_re/SSS/g;
print $line;

# Escaped single quotes embedded
$line = qq{Test #2 'Show me Wayne\\'s world','Jenny\\'s Basketball sho
+es'\n};
print $line;
$line =~ s/$single_quote_re/SSS/g;
print $line;

# Literal backslash before closing single quote
$line = qq{Test #2 'Show me Waynes world\\\\','Jenny\\'s Basketball sh
+oes'\n};
print $line;
$line =~ s/$single_quote_re/SSS/g;
print $line;
__END__
[download]

- Miller

Another regular expression resource and analysis tool I like is RegexBuddy (http://www.regexbuddy.com/). It's well worth its modest price tag of USD 39.95.

The creator of the software, Jan Goyvaerts, is the coauthor of Regular Expressions Cookbook (©2009, O'Reilly Media, Inc.), another fine resource.

s/(?|(')[^'\\]*(?:\\.[^'\\]*)*'|
     (")[^"\\]*(?:\\.[^"\\]*)*")/${1}SSS$1/gxs;
[download]

I just learned the (?|pattern) "branch reset" pattern from this post. It'll come in very handy—save me shenanigans—I'm sure. Thanks, ++JavaFan!