You are right with your guess that instead of writing to the "STDOUT" of the Mason component, your $image->Write('png:-') call writes the image somewhere else.

I suppose that this is a mod_perl limitation. Are you running Mason under mod_perl?
In a terminal program or with CGI both commands "print $header_templ" and "system('cat /my/templates/header.html')" will write to the same "STDOUT", but under mod_perl this is not so.

You have two options

1. Use Mason handler as CGI Script, in this case the following code works

   <%flags>
    inherit => undef
   </%flags>
   
   <%init>
       use Image::Magick;
   
       my $image = Image::Magick->new;
       $image->Set(size => '500 x 750');
       $image->Read('xc:black');
   
       STDOUT->autoflush(1);
       $r->content_type('image/png');
       $r->send_http_header;
   
       $image->Write("png:-");
   </%init>
   [download]

2. Unfortunately Image::Magick can't write to scalar or filehandle. So let Image::Magick to write the image to some tempfile, then open this tempfile again, read it into a scalar and print to STDOUT, or use the "$r->sendfile" method from mod_perl like this.

   <%flags>
    inherit => undef
   </%flags>
   
   <%init>
       use Image::Magick;
       use File::Temp;
   
       my $image = Image::Magick->new;
       $image->Set(size => '500 x 750');
       $image->Read('xc:green');
   
       my $temp = File::Temp->new( DIR => '/tmp', UNLINK => 1);
       my $temp_file_name = $temp->filename; 
   
       $image->Write("png:$temp_file_name");
   
       $r->content_type('image/png');
       $r->sendfile($temp_file_name);
   
       # File::Slurp and print could be used instead of $r->sendfile
       #
       #use File::Slurp; 
       #print read_file($temp_file_name);
   
   </%init>
   [download]