Are you sure you need the quoting at all? I did a quick test (on linux) and it seemed to work with spaces:

perl -e ' $t= "test and more.txt"; print "yes" if -T $t'

#prints
yes
[download]

It should work the same on windows I think

Testing W32 files names w/spaces:

#!/usr/bin/perl
use strict;
use warnings;

my $fullelementpath = "f:/_wo/haldane.txt";
if (-T $fullelementpath) {print "passed T\n";}else{print "failed for $
+fullelementpath\n";}
# -----------------------
my $fullelementpath2 = "f:/_wo/haldane space.txt";
if (-T $fullelementpath2) {print "passed T\n";}else{print "failed for 
+$fullelementpath2\n";}
[download]

Output:

C:\>pl_test\887602.pl
passed T
passed T

C:\>
[download]

Besides, AFAIK file tests like -T use the raw file name, spaces and all, as a parameter. So does 3 argument open. A peculiar exception is glob, for which a file pattern has to be quoted if it contains spaces.

"If there's not much weird stuff, then it looks like text".

Binary isn't as much fun: null bytes, unusual control chracters, bytes with the high bit set. Perl has to guess at what the file is most of the time, and it's right most of the time; however, sometimes it makes mistakes. If a file can't be read, doesn't exist, or is given an incorrect path, then Perl will say that it's not text and not binary. Maybe that's what is happening here. I would do a simple test on a few files to find out what's wrong. I used a simple if:

#!/usr/bin/perl

use strict;
use warnings;

my $fullelementpath = shift @ARGV;

if ( -T $fullelementpath) {
        print "This is a text file\n";
}
else {
        print "This is not a text file\n";
}
if ( -B $fullelementpath ) {
        print "This is a binary file\n";
}
else {
        print "This is not a binary file\n";
}
[download]

    open (FILE, "<" . $quotedfullelementpath) or die "Can't open file 
+$quotedfullelementpath:$!\n";
    while (<FILE>)
    {
      binmode(FILE);
      my $line1 = unpack("H*", $_);
      if ($line1 =~ /0d/)
[download]

You have the binmode in the wrong place.    You have to use it right after the open and before the while loop.

    open (FILE, "<" . $quotedfullelementpath) or die "Can't open file 
+$quotedfullelementpath:$!\n";
    binmode(FILE);
    while (<FILE>)
    {
[download]

Or you could set binmode from open:

    open (FILE, "<:raw" . $quotedfullelementpath) or die "Can't open f
+ile $quotedfullelementpath:$!\n";
    while (<FILE>)
    {
[download]

Because you are using unpack you could be matching one byte that has a "0" nybble and the next byte that has a "d" nybble, for example "10d2".    You need to just search for the byte that has the value "\x0d":

      if (/\x0d/)
[download]

Now that you have an answer to the spaces-in-filenames question, why not make things easier in terms of quoting? You have:

my $quotedfullelementpath = "\"" . $folderfullpath . "/" . $element . 
+"\"";
[download]

Of all the options available to you, you've settled for the most difficult and least attractive. You could use single quotes around the double quote characters, or the alternate single quote q. You could use a symbol constant to represent the quote and slash. Best of all, you could mash it all into a single string using qq! Assuming there was a real reason to put the double quotes in the string.

my $quotedfullelementpath = '"' . $folderfullpath . '/' . $element . '
+"';
my $quotedfullelementpath = q{"} . $folderfullpath . q{/} . $element .
+ q{"};

use Readonly;
Readonly my $DQUOTE => q{"};
Readonly my $SLASH  => q{/};

my $quotedfullelementpath 
    = $DQUOTE . $folderfullpath . $SLASH . $element . $DQUOTE;
my $quotedfullelementpath = qq{"$folderfullpath/$element "};
[download]

Why suffer when there are alternatives?