use warnings;
use strict;

my $s = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,bext,
+excellent" grade="7" teacher="Priyanka"}%';
if ($s =~ / \b teacher = " ([^"]+) " /x) {
    print "$1\n";
}

__END__

Priyanka
[download]

• perlre
• perlretut
• YAPE::Regex::Explain

You are thinking very complicated ;-)

Try to find the string teacher, a =", as few chars as possible, and then again a "

$var =~ /teacher="(.*?)"/;
[download]

HTH, Rata

>: perl -e 'print qq|$_\n| for q~%MYBOARD{project1|nameofproject1 rema
+rks="Good,Verygood,bext,excellent" grade="7" teacher="Priyanka"}%~=~m
+/grade="([^"]+).+teacher="([^"]+)/'
7
Priyanka
[download]

Heck, if you're going to do that, you might as well get it all:

#!/usr/bin/perl -w
use strict;

$_ = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,bext,exc
+ellent" grade="7" teacher="Priyanka"}%';

my %map;
$map{$1} = $2 while s/^.*? (\S+)="([^"]+)"//g;
print "$_: $map{$_}\n" for keys %map;
[download]

Output:

grade: 7
teacher: Priyanka
remarks: Good,Verygood,bext,excellent
[download]

The above can also be spelled

print map {"$1: $2\n" if /(\S+)="([^"]+)"/} split;
[download]

but I suspect that this would be a bit much for the OP... :)

-- 
Education is not the filling of a pail, but the lighting of a fire.
 -- W. B. Yeats

Hint 1: The code you claim will fetch a value won't compile.
Hint 2: Try substitution.
Hint 3: Read How do I post a question effectively?

use Modern::Perl;
use Data::Dumper;

my $text = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,be
+xt,excellent" grade="7" teacher="Priyanka"}%';

my %data = $text =~/ ([^=]+)="([^"]+)/g;

say Dumper(\%data);
[download]

$VAR1 = {
          'grade' => '7',
          'teacher' => 'Priyanka',
          'remarks' => 'Good,Verygood,bext,excellent'
        };
[download]