For date calculations use the cpan module: Date::Calc and possibly Date::Parse

Here's a quick and dirty script that takes the dates you specified and prints the difference in days between them. Note that there are differences between how Date::Parse treats month ranges and how Date::Calc does.

use Date::Parse;
use Date::Calc qw(Delta_Days);

use strict;

my $base = 'Jan 1, 1980';
my $start = 'Feb 1, 1981';
my $end = 'Feb 5, 1982';

print days_diff($start, $base) . "\n"; # 397
print days_diff($end, $base) . "\n"; # 766

sub days_diff {
    my $minuend = shift;
    my $subtrahend = shift;
    
    my (undef,undef,undef,$d2,$m2,$y2,undef) = strptime($minuend);
    my (undef,undef,undef,$d1,$m1,$y1,undef) = strptime($subtrahend);

    return Delta_Days($y1, $m1+1, $d1, $y2, $m2+1, $d2);
}

1;

__END__
[download]

use strict;
use warnings;
use feature qw( say );

use DateTime qw( );

# Or using your favourite DateTime::Format parser.
my $date1 = DateTime->new( year => 1981, month => 2, day => 1 );
my $date2 = DateTime->new( year => 1982, month => 2, day => 5 );
[download]

Part 1:

my $ref = DateTime->new( year => 1980, month => 1, day => 1 );
say $date1->delta_days($ref)->in_units('days');
say $date2->delta_days($ref)->in_units('days');
[download]

Part 2:

sub last_day_of_year {
   ( my $dt = DateTime->new( year => $_[0], month => 1, day => 1 ) )
      ->add( years => 1, days => -1 );
   return $dt->day_of_year();
}

my %in_range;
my $year1 = $date1->year();
my $year2 = $date2->year();
if ($year1 == $year2) {
   $in_range{$year1} = [ $date1->day_of_year()-1 .. $date2->day_of_yea
+r()-1 ];
} else {
   $in_range{$year1} = [ $date1->day_of_year()-1 .. last_day_of_year($
+year1)-1 ];
   for my $year ($year1+1 .. $year2-1) {
      $in_range{$year} = [ 0 .. last_day_of_year($year)-1 ];
   }
   $in_range{$year2} = [ 0 .. $date2->day_of_year()-1 ];
}

for my $year (sort { $a <=> $b } keys(%in_range)) {
   say "$year: @{ $in_range{$year} }";
}
[download]

PS - You said 365 where you should have said 364.

Update: Added part 2.

use Time::JulianDay;

my @start = (1981, 2, 1);
my @end   = (1982, 2, 5);
my $days = days('start' => \@start, 'end' => \@end, 'type' => 'yearly'
+);
my $days = days('start' => \@start, 'end' => \@end, 'type' => 'range')
+;

sub days {
    my (%a) = @_;
    
    my ($start, $end, $type) = ($a{'start'}, $a{'end'}, $a{'type'});
    
    if ($type eq 'range') {
        my $j0 = julian_day(1980, 1, 1);
        my $j1 = julian_day(@$start);
        my $j2 = julian_day(@$end);
        
        return (($j1 - $j0), ($j2 - $j0));
    }
    elsif ($type eq 'yearly') {
        my $start_year = $start->[0];
        my $end_year = $end->[0];
        
        my %days;
        for my $year ($start_year .. $end_year) {
            my $j0 = julian_day($year, 1, 1);
            my $j1; my $j2;
            if ($year == $start_year) {
                $j1 = julian_day($year, $start->[1], $start->[2]);
                $j2 = julian_day($year, 12, 31);
            }
            elsif ($year == $end_year) {
                $j1 = julian_day($year, 1, 1);
                $j2 = julian_day($year, $end->[1], $end->[2]);        
+    
            }
            else {
                $j1 = julian_day($year, 1, 1);
                $j2 = julian_day($year, 12, 31);
            }
            
            $days{"$year"} = [($j1 - $j0) .. ($j2 - $j0)];
        }
        
        return \%days;
    }
}
[download]