digirent:

You may find Hash::Util useful. By locking the keys of the hash, you'll get an error if you try to reference keys that don't exist:

$ cat hash_lock_keys.pl
#!/usr/bin/perl
use strict;
use warnings;
use Hash::Util qw(lock_keys);

my %f = (alpha=>1, beta=>2, gamma=>3);
lock_keys(%f);

if ($f{apple} == 4) {
    print "Eh?\n";
}

$ perl hash_lock_keys.pl
Attempt to access disallowed key 'apple' in a restricted hash at hash_
+lock_keys.pl line 9.
[download]

You can unlock the hash when you want to change it. The module has several other interesting-looking subroutines that you may find useful.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Maybe you want to use fields?

Thanks, I think the fields tip should do the trick! Greetings Matthieu

You probably want to use the exists function.

And a hash key cannot be undefined, only a hash value can be.

A simple tied hash definition would help:

#! perl -slw
use strict;
use 5.010;

{
    package debughash;
    require Tie::Hash;
    use Carp qw[ croak ];
    our @ISA = qw(Tie::Hash);

    sub TIEHASH {
        bless {}, $_[0];
    }

    sub FETCH {
        croak 'Non-existent key' unless exists $_[0]{ $_[1 ] };
        return $_[0]{ $_[1 ] };
    }

    sub STORE {
        return $_[0]{ $_[1 ] } = $_[2];
    }

}

use constant DEBUG => 1;

my %hash;
tie %hash, 'debughash' if DEBUG;

$hash{ 'exists' } = 1;

say $hash{ 'exists' };

say $hash{ 'nonexistant' };

__END__
C:\test>junk51
Non-existent key at C:\test\junk51.pl line 32
[download]