in reply to Re: Check if forked process is dead
in thread Check if forked process is dead

I'd like to know if I can check that process was not terminated by SIGTERM, so I'd SIGKILL it after some seconds. This doesn't work: 
$ perl -Mstrict -MPOSIX -wE 'my $pid = fork; if( $pid ){ kill TERM => 
+$pid; waitpid $pid => WNOHANG; say kill 0 => $pid;  } else { sleep 3;
+  exit; }'
1
$

[download]
But only 0 instead of WNOHANG shows me that process is ended.
Can I check if the process is ended in a limited amount of time?
Should I fork a new process only for a blocking waitpid $pid => 0 particularly?
Thank you.

Replies are listed 'Best First'.
Re^3: Check if forked process is dead
by Eliya (Vicar) on Mar 02, 2011 at 23:10 UTC

    You could inspect what the (non-blocking) waitpid returns. If it's the $pid, the process could be reaped successfully, which means it was no longer running.

    In your case here, you're calling the waitpid just a tad too early, so the preceding kill TERM hasn't been delivered/succeeded yet.  And as the waitpid $pid => WNOHANG couldn't yet reap at that moment, the process still exists as a zombie at the time you call kill 0  (like in your original case).

    Compare:

    Child reacts to SIGTERM: 

    #!/usr/bin/perl -wl
use strict;
use POSIX;

my $pid = fork;
if ( $pid ) {
    kill TERM => $pid;
    # wait for kill TERM to take effect
    select undef, undef, undef, 0.01;  
    my $reaped = waitpid $pid => WNOHANG;
    if ($reaped == $pid) {
        print "already gone.";         # <---
    } else {
        print "trying harder...";
        kill 9 => $pid;
    }
} else {
    sleep 3;
}

    [download]

    Child ignores SIGTERM: 

    #!/usr/bin/perl -wl
use strict;
use POSIX;

my $pid = fork;
if ( $pid ) {
    # give child some time to set up its $SIG{TERM} handler
    select undef, undef, undef, 0.01;
    kill TERM => $pid;
    select undef, undef, undef, 0.01;
    my $reaped = waitpid $pid => WNOHANG;
    if ($reaped == $pid) {
        print "already gone.";
    } else {
        print "trying harder...";      # <---
        kill 9 => $pid;
    }
} else {
    $SIG{TERM} = 'IGNORE';
    sleep 3;
}

    [download]
[reply]
[d/l]
[select]
      Hello,
      Great!
      I believe too I can save a syscall with returning value from waitpid instead of kill 0 trial.
      Special thanks for show that I can use select instead of usleep(). Is it about any advantages, besides few typing and probably that Time::HiRes is not yet included in Perl-5.8 distribution?
      I think I'd better use some specialized CPAN Test::* module for just to build FCGI::Spawn tests... ;-)
      Peter Vereshagin <peter@vereshagin.org>
[reply]
Re^3: Check if forked process is dead
by locked_user sundialsvc4 (Abbot) on Mar 03, 2011 at 20:46 UTC

    You cannot avoid race conditions in such a quest ...

In Section Seekers of Perl Wisdom