Expanding the solution to allow for reversing groups of multiple elements.

use strict;
use warnings;

use feature qw{ say };
use List::Util qw{ min };

my @arr = ( 1 .. 9 );
say qq{@arr};

my @twos = reverseGroupsOf( 2, @arr );
say qq{@twos};

my @threes = reverseGroupsOf( 3, @arr );
say qq{@threes};

my @fours = reverseGroupsOf( 4, @arr );
say qq{@fours};

sub reverseGroupsOf
{
    my $groupsOf = shift;
    my $rcReverse;
    $rcReverse = sub
       {
           reverse( map shift, 1 .. min scalar( @_, $groupsOf ),
           @_ ? &$rcReverse : ();
       };
    &$rcReverse;
}
[download]

1 2 3 4 5 6 7 8 9
2 1 4 3 6 5 8 7 9
3 2 1 6 5 4 9 8 7
4 3 2 1 8 7 6 5 9
[download]

I hope this is of interest.

I tend to like the mathematical solutions instead.

The following would let you reverse any N elements at a time in an array.

my @foo = (1..15);
my $n = 5;

my @bar = @foo[map {$_ + $n - 1 - 2 * ($_ % $n)} (0..$#foo)];

print "@bar";
[download]

Outputs

5 4 3 2 1 10 9 8 7 6 15 14 13 12 11
[download]

Obviously not as spiffy as using xor to switch odds and evens, but still pretty concise.

Alternatively, if you want to do a rotation of the elements instead of a reversal, you can use the following translation:

my @foo = (1..15);
my $n = 5;
my $i = 2;

my @bar = @foo[map {my $r = $_ % $n; $_ - $r + (($r + $i) % $n)} (0..$
+#foo)];

print "@bar";
[download]

Outputs

3 4 5 1 2 8 9 10 6 7 13 14 15 11 12
[download]

- Miller

I've always steered clear of using prototypes but I thought I'd have a go with them to see if I could come up with a general routine a bit like List::MoreUtils::natatime() but taking a code block rather than returning an iterator. This is what I came up with, putting a prototype declaration at the top of the script and fleshing out the subroutine later.

...
sub groupsOf (&$@);
...
sub groupsOf (&$@)
{
    my $rcToRun  = shift;
    my $groupsOf = shift;

    my $rcDoIt;
    $rcDoIt = sub
       {
           $rcToRun->( map shift, 1 .. min scalar( @_ ), $groupsOf ),
           @_ ? &$rcDoIt : ();
       };
    &$rcDoIt;
}
...
[download]

It seems to do the right thing. With regard to rotating the elements of an array, I would have thought the push @array, shift @array for 1 .. $n; idiom was easier to understand but others may disagree. Here is sub groupsOf() in action.

Read more... (1223 Bytes)

The output.

Read more... (551 Bytes)

I hope this is of interest.

Cheers,

JohnGG