Given the data you describe, this will plot a black pixel for the dots and a white pixel for the spaces:

#! perl -slw
use strict;
use GD;

my @d2D = map[
    map{ rand > 0.2 ? ' ' : '.'} 1 .. 1500
], 1 .. 1500;

my $i = GD::Image->new( 1500, 1500, 0 );
my $black = $i->colorAllocate( (0)x3 );
my $white = $i->colorAllocate( (255)x3 );

for my $y ( 0 .. 1499 ) {
    for my $x ( 0 .. 1499 ) {
        $i->setPixel( $x, $y,
            $d2D[ $y ][ $x ] eq ' ' ? $white : $black
        );
    }
}

open PNG, '>:raw', "$0.png" or die $!;
print PNG $i->png;
close PNG;

system 1, "$0.png";
[download]

Update: looking back at a previous post, perhaps this is what you are trying to do?

#! perl -slw
use strict;
use GD;

my $seq1 = join'',map{ (qw[ a c g t ] )[ rand 4 ] } 1 .. 1500;
my $seq2 = join'',map{ (qw[ a c g t ] )[ rand 4 ] } 1 .. 1500;

my $i = GD::Image->new( 1500, 1500, 0 );
my $black = $i->colorAllocate( (0)x3 );
my $white = $i->colorAllocate( (255)x3 );

for my $y ( 0 .. 1499 ) {
    for my $x ( 0 .. 1499 ) {
        $i->setPixel( $x, $y,
            substr( $seq1, $y, 1 ) eq substr( $seq2, $x, 1 )
                ? $black : $white
        );
    }
}

open PNG, '>:raw', "$0.png" or die $!;
print PNG $i->png;
close PNG;

system 1, "$0.png";
[download]

You could try GD::Graph. It has a number of sub classes for drawing different types of graph. From you description it sounds like you want a scatter graph, so you need GD::Graph::points.

All those graphing modules expect you to provide some arrays of data, and some other arguments representing the labels for each axis, what colours you want and the like. They return a GD bitmap object which you can save to disc or emit into a web page as part of a CGI script. You can probably also include it in a GUI, though I have not personally attempted to do that.

About 10 years ago, I was using the GD::Graph modules in a set of reporting scripts that I ran daily for the company I was working for at the time. Also contributed some patches. I have not used those modules since then.