It's easier than that. Try my $value = $objarray[72]{'apts'}[3][1];.

The thing to remeber is that Perl arrays and hashes only ever store scalar values, but a scalar can be a reference to something complicated like an array or a hash. Generally in Perl you use -> to dereference stuff, but Perl allows you to omit the -> when you have a nest of references as in the case you describe.

The other thing to remember is that in Perl the sigil tells you what type is returned so if you want a scalar value you need to use a $ up front.

Also, try reading the following perldoc's for additional information:

• perldsc - Perl Data Structures Cookbook
• perlref - Perl references and nested data structures

 my $value = $objarray[72]{'apts'}[3][1]

Thanks for the simple code, it works well.

I did read about arrays of hashes in the suggested sources, but it's not quite trivial to step up from there to "an array of hashes, each storing a 2D array".

The top level of the structure is an array, let's call it "objarray" ...

my @objarray = ();
[download]

...(about 90 elements). Each element of "objarray" is a hash.

my @objarray = (
    { },
    { },
   ({ }) x 87, # 87 more elements...
    { },
    );
[download]

One of the hash's keys is called "apts".

my @objarray = (
    { 'apts' => '???', },
    { 'apts' => '???', },
   ({ 'apts' => '???', }) x 87,
    { 'apts' => '???', },
    );
[download]

The value of that key is a 2D array ... consisting of 2 columns and several rows.

my @objarray = (
    { 'apts' => [ [11,12], [13,14], [15,16], ], },
    { 'apts' => [ [21,22], [23,24], [25,26], ], },
   ({ 'apts' => '???', }) x 87,
    { 'apts' => [ [91,92], [93,94], [95,96], ], },
    );
[download]

>perl -wMstrict -le
"my @objarray = (
     { 'apts' => [ [11,12], [13,14], [15,16], ], },
     { 'apts' => [ [21,22], [23,24], [25,26], ], },
    ({ 'apts' => '???', }) x 87,
     { 'apts' => [ [91,92], [93,94], [95,96], ], },
     );
 ;;
 print 'elements in array: ', scalar @objarray;
 print $objarray[89]{'apts'}[2][1];
"
elements in array: 90
96
[download]

(I cheated a bit on the construction of the array and so could not use the indices in the OP, but you get the idea.)

See also: How can I visualize my complex data structure?