If you are asking for guidance here, my first suggestion to you would be this:   that your true purpose here is, not “to create a Perl object that talks to a socket,” but rather “to create a Perl object that will serve as a black-box interface to a remote system.”

Of course, a search of CPAN (http://search.cpan.org) instantly points us to modules such as IO::Socket – this merely being among the first of 1,291 hits for the word, “socket.”   (Footnote:   A search for “ISO-8859-1” yields 248 more!)   Your Perl object can, and undoubtedly will, use such a package in its implementation.   But the purpose of this class (or, as the case may be, classes) will be, not only to handle the low-level mechanics of the basic protocol, but to intelligently and conveniently handle the messages, as well.

Ideally, no client of your module would have to care about where the server is (except for its IP-address and maybe port), nor exactly how it talks to you, nor exactly what it says.   The module becomes the perfect interpreter ambassador... excellent at what it does, so that nobody else has to.

(And if, at the conclusion of your due-diligence search of CPAN, it so happens that you have just invented a new CPAN module, please consider contributing it.)

Here's an 'OO-style' example (including a server part, so it can be run standalone):

#!/usr/bin/perl -w
use strict;
use IO::Socket;

my $pid = fork();
unless ($pid) {
    # --- server
    my $server = IO::Socket::INET->new(
        #LocalAddr => 'localhost',
        LocalPort => 12345,
        Proto     => "tcp",
        Listen    => SOMAXCONN, 
        Reuse     => 1,
    ) or die "couldn't create listening socket: $!";

    print "server listening...\n";
    
    while (1) {
        my $client = $server->accept();
        print "client connected\n";
        while (<$client>) {
            if (/^foo/) {
                $client->print("bar");       # 3 bytes (dummy)
                $client->print("0000001f");  # 8 bytes length as hex s
+tring
                $client->print("X" x 0x1f);  # data
                last;
            }
        }
        $client->close();
        print "connection closed\n";
    }
    exit;

} else {  # --- client
    sleep 1;

    my $conn = MyConnection->new('localhost', 12345);
    $conn->WriteInfo("foo\n");
    my $data = $conn->ReadData();
    print "data: '$data'\n";
}

END {
    kill 15, $pid;
    print "server shut down\n";
}


package MyConnection;
use base "IO::Socket::INET";

sub new {
    my $class = shift;
    my ($addr, $port) = @_;

    my $socket = IO::Socket::INET->new(
        Proto    => "tcp",
        PeerAddr => $addr,
        PeerPort => $port,
    ) or die "couldn't connect: $!";

    $socket->autoflush();
    return bless $socket, $class;
}

sub WriteInfo {
    my $sock = shift;
    my $info = shift;
    print "client sending request\n";
    $sock->print($info);
}

sub ReadData {
    my $sock = shift;
    $sock->read(my $dummy, 3);
    $sock->read(my $len_hex, 8);  
    my $len = hex($len_hex);
    print "client reading response ($len bytes)\n";
    $sock->read(my $data, $len);
    return $data;
}
[download]

$ ./892650.pl 
server listening...
client connected
client sending request
client reading response (31 bytes)
data: 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
connection closed
server shut down
[download]

Thank you Eliya..i think this will work.