I find it often helps to write small test scripts to figure out how to solve a specific problem. They often look something like:

use strict;  
use warnings;

while (<DATA>) {
    next if ! /PP: \((\d+)\)/;
    print "Matched $1\n";
}

__DATA__
PP: (899040) Jane Smith
[download]

where the __DATA__ section contains a selection of different lines to exercise the match.

use warnings;
use strict;

while (<DATA>) {
    s/[()]//g;
    print;
}

__DATA__
PP: (899040) Jane Smith
[download]

prints:

PP: 899040 Jane Smith
[download]

Update: similarly, you can use tr:

    tr/()//d;
[download]

Nit: the "8945" in your last code block, "the output...6 digits number" doesn't seem to bear any direct relationship to the data sample you provided. It's not crucial to our understanding -- in this case! -- but generally, you do need to be careful to cut and paste accurately to avoid sending us off on wild goose chases.

More substantially, the regex, $test=~s/\([\d.+]|[\d.+]\)//g often won't do what you appear to expect, as (ignoring the attempt to match parentheses) it matches any digit, followed by one_or_more of anything (digit or not). For help on that -- in other words, to see why you got two sets of two digits -- reread about quantifiers.

And, my suggestion would be that you'll learn more by doing so before reading the below:

Often combining split() and regex is very powerful. And can result in a regex that is easier to write and understand. The code below essentially says: delete the parens (if any) around the 2nd thing in the line where "things" are sequences of characters separated by spaces. This may or may not be all that you need, but without more than one test case, I have no way to determine that.

Also there can be reasons why it is desirable to "slurp" all of the data in a file into a memory resident array as in @fileinput=<$file>;, but in general when processing files line by line, this is not a good idea as it wastes memory and is slower than: read line, process line, read next line, etc. Also when doing a file operation, like "open" check the status of the open - it is very possible that an "open()" can fail: file does not exits, wrong permissions, etc.

As Grandfather points out, DATA is an already open file handle that can read data from within your Perl code as shown below. This is extremely useful for testing.

#!/usr/bin/perl -w
use strict;

while (<DATA>)
{
   my ($id, $num, $rest) = split(/\s+/, $_, 3);
   $num =~ tr/()//d; #deletes parens in num field
   print "$id $num $rest";
}

#prints:
#PP: 899040 Jane Smith
#PP: 899040 Jane (Smith)
#PP: 899040 Jane (Smith)

__DATA__
PP: (899040) Jane Smith
PP: 899040   Jane (Smith)
PP: (899040) Jane (Smith)
[download]