NevilleG has asked for the wisdom of the Perl Monks concerning the following question:

Hi. I am seeing some strange behaviour using Perl's pattern matching and capturing. It may be due to my lack of understanding of how it works, but I've been staring at it for a solid day and a half without success. Basically the pattern search is only being done once for the same string, even though I want to loop through an array of strings (some of the array elements are the same). Here's the test program: 

#!/usr/bin/perl
use strict ;
########################################################
######## START MAIN ####################
my @STAGE=(
   '/stage/core/HPUX/PA-RISC-64/64bit/rdbms/10.2.0.1.0/dvd2/clusterwar
+e',
   '/stage/core/HPUX/PA-RISC-64/64bit/rdbms/patches/10.2.0.4.0/Disk1'
        ) ;
my $i ;
my $j ;
 
for ($i=0; $i<=5; $i++){
   my $o_vers ;
   $j = $i - int($i/2)*2 ;
   $o_vers = $1 if $STAGE[$j] =~ ?/rdbms/([\d.]+)/? ;
   $o_vers = $1 if $STAGE[$j] =~ ?/rdbms/patches/([\d.]+)/? ;
   print "Iteration# $i: Version is: $o_vers\n" ;
}

[download]

This produces the following output:

[root@moops perl]# t10f.pl
Iteration# 0: Version is: 10.2.0.1.0
Iteration# 1: Version is: 10.2.0.4.0
Iteration# 2: Version is:
Iteration# 3: Version is:
Iteration# 4: Version is:
Iteration# 5: Version is:
[root@moops perl]#

[download]

-Why is the version not being printed after the first 2 iterations through the loop? -Please help explain this behaviour to this Perl simpleton... Thanks in advance, Neville

Replies are listed 'Best First'.
Re: Pattern matching & capturing strange behaviour.
by ikegami (Patriarch) on Mar 22, 2011 at 00:54 UTC

    From perlop, "«?pattern?» is just like the «/pattern/» search, except that it matches only once between calls to the reset() operator."

    You clearly didn't mean to use the ?pattern? operator. Fix: 

       $o_vers = $1 if $STAGE[$j] =~ m{/rdbms/([\d.]+)/} ;
   $o_vers = $1 if $STAGE[$j] =~ m{/rdbms/patches/([\d.]+)/} ;

    [download]
[reply]
[d/l]
[select]
Re: Pattern matching & capturing strange behaviour.
by wind (Priest) on Mar 22, 2011 at 00:52 UTC

    The problem is fixed by specifying your regex using m{} instead of ??.

    #!/usr/bin/perl
use strict ;
########################################################
######## START MAIN ####################
my @STAGE=(
    '/stage/core/HPUX/PA-RISC-64/64bit/rdbms/10.2.0.1.0/dvd2/clusterwa
+re',
    '/stage/core/HPUX/PA-RISC-64/64bit/rdbms/patches/10.2.0.4.0/Disk1'
);

for my $i (0..5){
   my $o_vers ;
   my $j = $i & 1;
   $o_vers = $1 if $STAGE[$j] =~ m{/rdbms/([\d.]+)/};
   $o_vers = $1 if $STAGE[$j] =~ m{/rdbms/patches/([\d.]+)/};
   print "Iteration# $i: Version is: $o_vers\n" ;
}

    [download]

    Also note, you could combine your two regex's like so:

    for my $i (0..5){
   my $j = $i & 1;
   my $o_vers = $STAGE[$j] =~ m{/rdbms/(?:patches/)?([\d.]+)/} ? $1 : 
+'';
   print "Iteration# $i: Version is: $o_vers\n" ;
}

    [download]

    - Miller

[reply]
[d/l]
[select]
      Thanks a ton. That did the trick. I was only using '?' as a different delimiter to '/'. Didn't realise the full implication.
[reply]

Back to Seekers of Perl Wisdom