Re^5: Error using grep

Ok. A fairly full on version of that looks like this:

#!/usr/bin/perl
use strict;
use warnings;
use Getopt::Long;

my %options;

Getopt::Long::GetOptions(\%options, 'all', 'keyword:s', 'help');

my @filenames = @ARGV;

if (!exists $options{keyword} || !@filenames || exists $options{help})
+ {
    print <<HELP;
search [--all] --keyword <match word> <file list>

    Searches all files in <file list> and prints the lines where <matc
+h word>
    is found. If --all is provided the entire file containing <match w
+ord> is
    printed.
HELP

    exit;
}

my $found;

for my $fileName (@filenames) {
    open my $inFile, '<', $fileName or die "Unable to open $fileName: 
+$!\n";

    while (defined(my $line = <$inFile>)) {
        next if $line !~ /\b\Q$options{keyword}\E\b/;

        if ($options{all}) {
            print "\nKeyword $options{keyword} found on line $. of $fi
+leName\n";
            seek $inFile, 0, 0;
            print <$inFile>;
            $found = 1;
            last;
        }

        print $line;
        $found = 1;
    }

    close $inFile;
}

print "Keyword not found in ", join(', ', @filenames), "\n" if !$found
+;
[download]

There are a few things to note in that code:

The command line is used to give switches and the list of files to process
The module Getopt::Long is used to process command line switches
The script gives help if it doesn't like the command line parameters or help is asked for using the --help switch
Three parameter open is used and the result checked.
Lexical file handles (my $inFile) are used
seek is used to set the input file back to the start so a simple print <$inFile>; can be used to print the entire file
A found flag is used to keep track of wether a match has been found or not.

A typical command line looks like:

search --keyword "Boot Flash" --all file1.txt file2.txt
[download]

True laziness is hard work

Comment on Re^5: Error using grep Select or Download Code

Replies are listed 'Best First'.
Re^6: Error using grep by justkar4u (Novice) on Mar 29, 2011 at 23:00 UTC
Hi, I appreciate your help but I tried to execute your code and I got search command not found error! I tried to use switch command instead but still same error. Your code exits after showing HELP. Finally I was able to fix it :) #!/usr/bin/perl use strict; use warnings; if ($#ARGV != 1) { print "Error: Usage- script.pl filename keyword(to be searched)\neg:se +arch.pl config_file XYZ\n"; exit; } our $file=$ARGV[0]; our $key=$ARGV[1]; my $count = 0; if (-e "$file") { open (DATA,$file); chomp($key); # Search for the key pattern in the file information. while (defined (my $line = <DATA>)) { if ($line =~ /\b\Q$key\E\b/i) { #next; print "$line\n"; $count++; } } if($count == 0) { print "Keyword not found\n Search Completed\n"; } close (DATA); } else { print "Error: file does'nt exist\n"; exit; } [download] NOTE: This can be run as script.pl randomfile randomkey format	[reply] [d/l]

Replies are listed 'Best First'.

Re^6: Error using grep
by justkar4u (Novice) on Mar 29, 2011 at 23:00 UTC

#!/usr/bin/perl
use strict;
use warnings;
if ($#ARGV != 1) 
{
print "Error: Usage- script.pl filename keyword(to be searched)\neg:se
+arch.pl config_file XYZ\n";
exit;
}
our $file=$ARGV[0];
our $key=$ARGV[1];
my $count = 0;
    if (-e "$file")
    {
    open (DATA,$file); 
    chomp($key);
    # Search for the key pattern in the file information.
    while (defined (my $line = <DATA>)) 
        {
            if ($line =~ /\b\Q$key\E\b/i)
            {
            #next;
                print "$line\n";
            $count++;
            } 
        }
    if($count == 0)
        {
        print "Keyword not found\n Search Completed\n";
        }
    close (DATA);
    }
    else 
    {
        print "Error: file does'nt exist\n";
        exit;
    }
[download]

[reply]
[d/l]