Without telling us what the script should do it is very difficult telling you exactly whats wrong. So I can only guess what you want

1) In your subroutine shuffle you use the global variables @starting_deck and @random_card, this probably is wrong when you call shuffle with $file as parameter. It also makes your script behave quite random, more about this later. Generally you should avoid using global variables in subroutines and give all necessary information as a parameter to the subroutine.

2) You use "my $card= shift(@_);". This is ok if you only call the subroutine with one card, but when you do "shuffle(@starting_deck)", you only get to use the first value. What you probably meant was something like this:

my @newdeck= shuffle(@starting_deck);

sub shuffle {
  my @cards= @_;
  foreach (1...30) {
    my @cut= pop(@cards), shift (@cards), pop(@cards) ...
    ...
    push @cards, @cut;
  }
  ...
  return @˘ards;
}
[download]

3) You try to for example substitue 'C' with Clubs'. If you do that more than once, you will produce 'Clubslubs'. So just do that once, maybe in a different subroutine (because really it has nothing to do with shuffling), before or after the shuffling.

Debugging: If your program is not working like you expect, put in 'print' statements to tell you what the program does. Even better, use Data::Dumper to print out your variables and you will get insights into its inner workings

For example you could have added to your old shuffle subroutine something like

use Data::Dumper; # <-better put this at the beginning of your script,
+ but works here too

print Dumper(\@starting_deck);
[download]

You would have noticed then that your subroutine is only executed twice, because you change @random_card in the subroutine while your main script is stepping through @random_card in the foreach loop. @random_card gets emptied and so the foreach ends prematurely. If this is on purpose, ok, but don't think for a moment you can ever return to this script in a few months and change anything without completely breaking the script.

It looks like you just want to shuffle a deck of cards. If this is the case, then take a look at the module List::Util and shuffle. Here is your code redone using shuffle to order the cards randomly:

#!/usr/bin/perl -w

use List::Util qw(shuffle);

use strict;
use warnings;

my @cards = (2..10,qw(J Q K A));
my @suits = qw(h d c s);
my @deck = map {my $suit = $_; map {"$_$suit"} @cards} @suits;

my @newdeck = shuffle(@deck);

print "@newdeck\n";
[download]

Global symbol "@startingdeck" requires explicit package name at pm8964
+10.pl line 6.
Global symbol "@random_card" requires explicit package name at pm89641
+0.pl line 14.
Global symbol "@startingdeck" requires explicit package name at pm8964
+10.pl line 14.
Global symbol "$file" requires explicit package name at pm896410.pl li
+ne 16.
Global symbol "@random_card" requires explicit package name at pm89641
+0.pl line 16.
Global symbol "@starting_deck" requires explicit package name at pm896
+410.pl line 17.
Global symbol "$file" requires explicit package name at pm896410.pl li
+ne 17.
[download]

#!/usr/bin/perl 

use strict;
use warnings;
use Data::Dumper;

my @deck = ("A H","2 H","3 H","4 H","5 H","6 H","7 H",
            "8 H","9 H","10 H","J H","Q H","K H",
            "A D","2 D","3 D","4 D","5 D","6 D","7 D",
            "8 D","9 D","10 D","J D","Q D","K D",
            "A C","2 C","3 C","4 C","5 C","6 C","7 C",
            "8 C","9 C","10 C","J C","Q C","K C",
            "A S","2 S","3 S","4 S","5 S","6 S","7 S",
            "8 S","9 S","10 S","J S","Q S","K S");

fisher_yates_shuffle(\@deck);
print Dumper(\@deck);

sub fisher_yates_shuffle { 
    my $deck = shift;
    return unless @$deck;
        
    my $i = @$deck;
    while (--$i) {
        my $j = int rand ($i+1);
        @$deck[$i,$j] = @$deck[$j,$i];
    }
}
[download]